From ac778f2cf394586c43beb5d753a19ff3f6063556 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 8 Dec 2023 05:11:05 +0000
Subject: gentoo auto-resync : 08:12:2023 - 05:11:04

---
 dev-scheme/chez/Manifest             |  2 +-
 dev-scheme/chez/chez-9.6.4-r1.ebuild | 97 ++++++++++++++++++++++++++++++++++++
 dev-scheme/chez/chez-9.6.4.ebuild    | 75 ----------------------------
 3 files changed, 98 insertions(+), 76 deletions(-)
 create mode 100644 dev-scheme/chez/chez-9.6.4-r1.ebuild
 delete mode 100644 dev-scheme/chez/chez-9.6.4.ebuild

(limited to 'dev-scheme/chez')

diff --git a/dev-scheme/chez/Manifest b/dev-scheme/chez/Manifest
index 0442c5c7532b..1ce6c557c2cb 100644
--- a/dev-scheme/chez/Manifest
+++ b/dev-scheme/chez/Manifest
@@ -1,5 +1,5 @@
 DIST chez-9.6.2.tar.gz 35691078 BLAKE2B f8436754eca64ac2b1cd9138c546b31a9ae0c05ae8f7d8afd74205e2c03289050354b6bb03cfa9d26b887f0606dd9410d0a8bc8f2da517a6132781dfaa18a243 SHA512 65b6a1dce571568dcc9725086b41065a7c7d56eab10eb78039da192dfbb91568d2bec72005e8ce84cefe3ba87220fdb3aa870e9f05e60fbf2b838f4467cb4a52
 DIST chez-9.6.4.tar.gz 35679113 BLAKE2B dd008181caa7b74d35fed4a67dbbf2719af9ab7288ac6b5577fe2caf3ba4f34c5f9192fe2ca08b00d48e16d75b6c82324c1f222fe4fd321649d109dd221ffc40 SHA512 00c33650d0f980c9d28ad4871c97da67b9f25e3fde5a3188b2bbbc9cc813e63e3c9055bc6a94addedbea52cd531cbb56bcdc5e2fda6c6ca37b30166c2797e53a
 EBUILD chez-9.6.2.ebuild 1812 BLAKE2B 72955ce1fff269ee0a560b02446fb59a6acd853098911903aadda833396b8a14067e2fb58189a5f9fc6f28f01e9b287c1b82917bb9199f12b871e966f65883d8 SHA512 f5f9583fe24834f4a7548ccd10d3659e111ff07e5fe64e041adb7aba4e1001a02e8cef5e60b42897f9690f6429d88a439e74755c9a0508fdc4a7ef1539182725
-EBUILD chez-9.6.4.ebuild 1814 BLAKE2B 4fcfa6b02f5cd9a43c0a38df8b6f25ec774405157f41fcb2296b2d9939e36552b7d583bc79b69660f4c58639d3a89246a8f6f68677b197456b9998441889c007 SHA512 6ffc289b819ce4099dd85157c45f6f9cc7adf17c664866c33503abe138ad2c02312d1586a25ebd8d04cfb4bd598d9b4b59993bbacac1ab70018ea9ba33818f35
+EBUILD chez-9.6.4-r1.ebuild 2222 BLAKE2B 475087f061873898d227a4038835cbbec1224205911974dc0a8380172fe1c6d6625d0863defaf99afa634e08a75fe20ae1f753997a536dccd28a0575d617a16e SHA512 8c27c4acd0b82a79e4bd73e0fa99dfa468a1569f5222e21259f2b27bfcc0742d4f8894989a1312bb5713b82b4ca5d080faec994e3e586b548f5f53f115041622
 MISC metadata.xml 1247 BLAKE2B 2fce457107f3e9a65f30ecc19c891c1b953049889bcd7bd9ccc7537c6ee8b9ae64937ee46c329f74266f095fd611ae53775e4229aacd4ebdf82b83135e13e50c SHA512 2a0bab06ce23b7e38f4651d33337b03691dbe09257ee325236ad5c585af4300e2b15f6b0d9614ee87ee4721adebfd71c0a2313ad3865a9e7f75e5e95b54cc5a3
diff --git a/dev-scheme/chez/chez-9.6.4-r1.ebuild b/dev-scheme/chez/chez-9.6.4-r1.ebuild
new file mode 100644
index 000000000000..2e64fdec637c
--- /dev/null
+++ b/dev-scheme/chez/chez-9.6.4-r1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit edo toolchain-funcs
+
+DESCRIPTION="A programming language based on R6RS"
+HOMEPAGE="https://cisco.github.io/ChezScheme/
+	https://github.com/cisco/ChezScheme/"
+SRC_URI="https://github.com/cisco/ChezScheme/releases/download/v${PV}/csv${PV//a}.tar.gz
+	-> ${P}.tar.gz"
+S="${WORKDIR}/csv${PV//a}"
+
+# Chez Scheme itself is Apache 2.0, but it vendors Nanopass and stex
+# which are both MIT licensed.
+LICENSE="Apache-2.0 MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86"
+IUSE="X ncurses threads"
+
+RDEPEND="
+	app-arch/lz4:=
+	sys-apps/util-linux
+	sys-libs/zlib:=
+	X? ( x11-libs/libX11 )
+	ncurses? ( sys-libs/ncurses:= )
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	tc-export AR CC CXX LD RANLIB
+
+	default
+
+	if use ncurses ; then
+		local nclibs="\"$($(tc-getPKG_CONFIG) --libs ncurses)\""
+
+		sed -i "s|ncursesLib=-lncurses|ncursesLib=${nclibs}|g" configure || die
+	fi
+
+	# Remove -Werror
+	sed -i "/^C = /s|-Werror||g" c/Mf-* || die
+}
+
+src_configure() {
+	# See official docs for translation guide.
+	# https://cisco.github.io/ChezScheme/release_notes/v9.6/release_notes.html
+	# "t" for threading + arch_map + "le" for Linux (hardcoded for now)
+	local -A arch_map=(
+		[amd64]=a6
+		[arm]=arm32
+		[ppc]=ppc32
+		[x86]=i3
+	)
+	local machine="$(usex threads 't' '')${arch_map[${ARCH}]}le"
+
+	local -a myconfargs=(
+		--machine="${machine}"
+		--libkernel
+		--nogzip-man-pages
+
+		--installprefix="/usr"
+		--installbin="/usr/bin"
+		--installlib="/usr/$(get_libdir)"
+		--installman="/usr/share/man"
+		--installschemename=chezscheme
+		--installpetitename=chezscheme-petite
+		--installscriptname=chezscheme-script
+
+		$(usex threads '--threads' '')
+		$(usex ncurses '' '--disable-curses')
+		$(usex X '' '--disable-x11')
+
+		AR="$(tc-getAR)"
+		CC="$(tc-getCC)"
+		LD="$(tc-getLD)"
+
+		LZ4="$($(tc-getPKG_CONFIG) --libs liblz4)"
+		ZLIB="$($(tc-getPKG_CONFIG) --libs zlib)"
+	)
+	edob sh ./configure "${myconfargs[@]}"
+}
+
+src_install() {
+	# TempRoot == DESTDIR
+	emake TempRoot="${ED}" install
+	einstalldocs
+
+	find "${ED}/usr/$(get_libdir)/csv${PV//a}/examples" \
+		 \( -name "*.md" -o -name "*.so" \)  -delete || die
+}
diff --git a/dev-scheme/chez/chez-9.6.4.ebuild b/dev-scheme/chez/chez-9.6.4.ebuild
deleted file mode 100644
index dad71cf90e84..000000000000
--- a/dev-scheme/chez/chez-9.6.4.ebuild
+++ /dev/null
@@ -1,75 +0,0 @@
-# Copyright 2021-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit toolchain-funcs
-
-DESCRIPTION="A programming language based on R6RS"
-HOMEPAGE="https://cisco.github.io/ChezScheme/ https://github.com/cisco/ChezScheme"
-SRC_URI="https://github.com/cisco/ChezScheme/releases/download/v${PV}/csv${PV//a}.tar.gz
-	-> ${P}.tar.gz"
-S="${WORKDIR}"/csv${PV//a}
-
-# Chez Scheme itself is Apache 2.0, but it vendors Nanopass and stex
-# which are both MIT licensed.
-LICENSE="Apache-2.0 MIT"
-SLOT="0/${PV}"
-KEYWORDS="~amd64 ~x86"
-IUSE="X ncurses threads"
-
-BDEPEND="virtual/pkgconfig"
-RDEPEND="
-	app-arch/lz4:=
-	sys-apps/util-linux
-	sys-libs/zlib:=
-	ncurses? ( sys-libs/ncurses:= )
-"
-DEPEND="${RDEPEND}"
-RDEPEND="
-	${RDEPEND}
-	X? ( x11-libs/libX11 )
-"
-
-src_prepare() {
-	tc-export AR CC CXX LD RANLIB
-
-	default
-
-	if use ncurses ; then
-		local nclibs="\"$($(tc-getPKG_CONFIG) --libs ncurses)\""
-		sed -i "s|ncursesLib=-lncurses|ncursesLib=${nclibs}|g" configure || die
-	fi
-
-	# Remove -Werror
-	sed -i "/^C = /s|-Werror||g" c/Mf-* || die
-}
-
-src_configure() {
-	local myconfargs=(
-		$(usex threads '--threads' '')
-		$(usex ncurses '' '--disable-curses')
-		$(usex X '' '--disable-x11')
-		--installprefix="/usr"
-		--installbin="/usr/bin"
-		--installlib="/usr/$(get_libdir)"
-		--installman="/usr/share/man"
-		--installschemename=chezscheme
-		--installpetitename=chezscheme-petite
-		--installscriptname=chezscheme-script
-		--libkernel
-		--nogzip-man-pages
-		LZ4=$($(tc-getPKG_CONFIG) --libs liblz4)
-		ZLIB=$($(tc-getPKG_CONFIG) --libs zlib)
-	)
-	sh ./configure "${myconfargs[@]}" || die
-}
-
-src_install() {
-	# TempRoot == DESTDIR
-	emake TempRoot="${ED}" install
-	einstalldocs
-
-	find "${ED}"/usr/$(get_libdir)/csv${PV//a}/examples \
-		 \( -name "*.md" -o -name "*.so" \)  -delete || die
-}
-- 
cgit v1.2.3