From 8c8f1cfd2aa9e839aad7dad6fd43b370cfbc0a1e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 10 Jan 2024 13:02:42 +0000
Subject: gentoo auto-resync : 10:01:2024 - 13:02:42

---
 dev-ruby/sshkit/sshkit-1.22.0.ebuild | 43 ++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 dev-ruby/sshkit/sshkit-1.22.0.ebuild

(limited to 'dev-ruby/sshkit/sshkit-1.22.0.ebuild')

diff --git a/dev-ruby/sshkit/sshkit-1.22.0.ebuild b/dev-ruby/sshkit/sshkit-1.22.0.ebuild
new file mode 100644
index 000000000000..e5a34a057ff2
--- /dev/null
+++ b/dev-ruby/sshkit/sshkit-1.22.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby31 ruby32"
+
+# There are functional tests that require vagrant boxes to be set up.
+RUBY_FAKEGEM_TASK_TEST="test:units"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md FAQ.md README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="SSHKit makes it easy to write structured, testable SSH commands in Ruby"
+HOMEPAGE="https://github.com/capistrano/sshkit"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+ruby_add_rdepend "
+	dev-ruby/mutex_m
+	>=dev-ruby/net-ssh-2.8.0:*
+	>=dev-ruby/net-scp-1.1.2
+	>=dev-ruby/net-sftp-2.1.2
+"
+
+ruby_add_bdepend "test? ( dev-ruby/minitest dev-ruby/mocha )"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/I s:^:#:' Rakefile test/helper.rb || die
+	sed -e '/\(turn\|unindent\|reporters\)/I s:^:#:' \
+		-e '1irequire "pathname"' \
+		-i test/helper.rb || die
+
+	# Fix assumption about parent directory name
+	sed -i -e '/assert_match/ s/sshkit/sshkit.*/' test/unit/test_deprecation_logger.rb || die
+}
+
+each_ruby_test() {
+	# Run tests directly to avoid dependencies in the Rakefile
+	${RUBY} -Ilib:test:. -e "Dir['test/unit/**/test*.rb'].each{|f| require f}" || die
+}
-- 
cgit v1.2.3