From 398c033d3c836f59a4f2668f3c27b680b7ed1f54 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 6 Sep 2022 10:26:32 +0100
Subject: gentoo auto-resync : 06:09:2022 - 10:26:32

---
 dev-ruby/sshkit/sshkit-1.21.3.ebuild | 43 ++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 dev-ruby/sshkit/sshkit-1.21.3.ebuild

(limited to 'dev-ruby/sshkit/sshkit-1.21.3.ebuild')

diff --git a/dev-ruby/sshkit/sshkit-1.21.3.ebuild b/dev-ruby/sshkit/sshkit-1.21.3.ebuild
new file mode 100644
index 000000000000..0c59a5fd2f75
--- /dev/null
+++ b/dev-ruby/sshkit/sshkit-1.21.3.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby27 ruby30"
+
+# There are functional tests that require vagrant boxes to be set up.
+RUBY_FAKEGEM_TASK_TEST="test:units"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md FAQ.md README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="SSHKit makes it easy to write structured, testable SSH commands in Ruby"
+HOMEPAGE="https://github.com/capistrano/sshkit"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+ruby_add_rdepend "
+	>=dev-ruby/net-ssh-2.8.0:*
+	>=dev-ruby/net-scp-1.1.2
+"
+
+ruby_add_bdepend "test? ( dev-ruby/minitest dev-ruby/mocha <dev-ruby/net-ssh-7 )"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/I s:^:#:' Rakefile test/helper.rb || die
+	sed -e '/\(turn\|unindent\|reporters\)/I s:^:#:' \
+		-e '1irequire "set"; require "pathname"' \
+		-e '1igem "net-ssh", "<7"' \
+		-i test/helper.rb || die
+
+	# Fix assumption about parent directory name
+	sed -i -e '/assert_match/ s/sshkit/sshkit.*/' test/unit/test_deprecation_logger.rb || die
+}
+
+each_ruby_test() {
+	# Run tests directly to avoid dependencies in the Rakefile
+	${RUBY} -Ilib:test:. -e "Dir['test/unit/**/test*.rb'].each{|f| require f}" || die
+}
-- 
cgit v1.2.3