From 401101f9c8077911929d3f2b60a37098460a5d89 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 24 Mar 2022 23:59:54 +0000
Subject: gentoo resync : 25.03.2022

---
 dev-ruby/rexical/rexical-1.0.7-r1.ebuild | 42 ++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 dev-ruby/rexical/rexical-1.0.7-r1.ebuild

(limited to 'dev-ruby/rexical/rexical-1.0.7-r1.ebuild')

diff --git a/dev-ruby/rexical/rexical-1.0.7-r1.ebuild b/dev-ruby/rexical/rexical-1.0.7-r1.ebuild
new file mode 100644
index 000000000000..097ddac4f886
--- /dev/null
+++ b/dev-ruby/rexical/rexical-1.0.7-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby26 ruby27 ruby30 ruby31"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.rdoc	DOCUMENTATION.en.rdoc  DOCUMENTATION.ja.rdoc  README.ja  README.rdoc"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Rexical is a lexical scanner generator"
+HOMEPAGE="https://github.com/tenderlove/rexical/tree/master"
+LICENSE="LGPL-2" # plus exception
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+SLOT="0"
+IUSE=""
+
+# File collision, bug 459116
+RDEPEND+=" !!app-admin/rex"
+
+ruby_add_bdepend "
+	test? (
+		dev-ruby/minitest
+	)"
+
+all_ruby_prepare() {
+	# Avoid dependency on unpackaged rubocop
+	sed -i -e '/test_rubocop_security/askip "not packaged"' test/test_generator.rb || die
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib:.:test -e 'Dir["test/test_*.rb"].each{|f| require f}' || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	docinto examples
+	dodoc sample/*
+}
-- 
cgit v1.2.3