From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 dev-ruby/msgpack/msgpack-1.1.0.ebuild | 44 +++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 dev-ruby/msgpack/msgpack-1.1.0.ebuild

(limited to 'dev-ruby/msgpack/msgpack-1.1.0.ebuild')

diff --git a/dev-ruby/msgpack/msgpack-1.1.0.ebuild b/dev-ruby/msgpack/msgpack-1.1.0.ebuild
new file mode 100644
index 000000000000..08bed06564e4
--- /dev/null
+++ b/dev-ruby/msgpack/msgpack-1.1.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+USE_RUBY="ruby21 ruby22 ruby23"
+
+RUBY_FAKEGEM_TASK_DOC="doc"
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+RUBY_FAKEGEM_EXTRADOC="README.rdoc"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="Binary-based efficient data interchange format for ruby binding"
+HOMEPAGE="https://msgpack.org/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86 ~x86-fbsd"
+IUSE="doc"
+
+ruby_add_bdepend "doc? ( dev-ruby/yard )"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/I s:^:#:' Rakefile || die
+
+	# Remove jruby-specific specs that are run also for other rubies.
+	rm -rf spec/jruby || die
+
+	sed -i -e '/git ls-files/d' msgpack.gemspec || die
+}
+
+each_ruby_configure() {
+	${RUBY} -Cext/${PN} extconf.rb || die "Configuration of extension failed."
+
+	# rb_num2int is not inlined on 32 bit arches but also not explicitly
+	# defined, bug 582968
+	sed -i -e 's:-Wl,--no-undefined::' ext/${PN}/Makefile || die
+}
+
+each_ruby_compile() {
+	emake V=1 -Cext/${PN}
+	cp ext/${PN}/msgpack$(get_modname) lib/${PN} || die "Unable to install msgpack library."
+}
-- 
cgit v1.2.3