From 05b8b0e0af1d72e51a3ee61522941bf7605cd01c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 4 Jul 2020 14:05:23 +0100
Subject: gentoo resync : 04.07.2020

---
 dev-ruby/kramdown/kramdown-2.3.0.ebuild | 52 +++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 dev-ruby/kramdown/kramdown-2.3.0.ebuild

(limited to 'dev-ruby/kramdown/kramdown-2.3.0.ebuild')

diff --git a/dev-ruby/kramdown/kramdown-2.3.0.ebuild b/dev-ruby/kramdown/kramdown-2.3.0.ebuild
new file mode 100644
index 000000000000..a94195768837
--- /dev/null
+++ b/dev-ruby/kramdown/kramdown-2.3.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+USE_RUBY="ruby25 ruby26"
+
+RUBY_FAKEGEM_EXTRADOC="README.md AUTHORS CONTRIBUTERS"
+
+RUBY_FAKEGEM_EXTRAINSTALL="data"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Yet-another-markdown-parser but fast, pure Ruby, using strict syntax definition"
+HOMEPAGE="https://kramdown.gettalong.org/"
+
+LICENSE="MIT"
+
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64"
+IUSE="latex"
+
+LATEX_DEPS="latex? ( dev-texlive/texlive-latex dev-texlive/texlive-latexextra )"
+RDEPEND+=" ${LATEX_DEPS}"
+DEPEND+=" test? ( ${LATEX_DEPS} app-text/tidy-html5 )"
+
+ruby_add_rdepend "
+	dev-ruby/rexml
+	>=dev-ruby/rouge-1.8
+	>=dev-ruby/stringex-1.5.1
+	!!<dev-ruby/kramdown-1.17.0-r2:0"
+
+ruby_add_bdepend "doc? ( dev-ruby/rdoc )
+	test? ( >=dev-ruby/minitest-5.0 )"
+
+all_ruby_prepare() {
+	if ! use latex; then
+		# Remove latex tests. They will fail gracefully when latex isn't
+		# present at all, but not when components are missing (most
+		# notable ucs.sty).
+		sed -i -e '/latex -v/,/^  end/ s:^:#:' test/test_files.rb || die
+	fi
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib:. -e "Dir['test/test_*.rb'].each{|f| require f}" || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	doman man/man1/kramdown.1
+}
-- 
cgit v1.2.3