From ca85c13c0f9c4f9af191bc9a46a7bc274e1d25bf Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 9 Jul 2023 10:24:33 +0100
Subject: gentoo auto-resync : 09:07:2023 - 10:24:32

---
 dev-ruby/io-console/io-console-0.6.0-r1.ebuild | 40 ++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 dev-ruby/io-console/io-console-0.6.0-r1.ebuild

(limited to 'dev-ruby/io-console/io-console-0.6.0-r1.ebuild')

diff --git a/dev-ruby/io-console/io-console-0.6.0-r1.ebuild b/dev-ruby/io-console/io-console-0.6.0-r1.ebuild
new file mode 100644
index 000000000000..54a0ae2fb86d
--- /dev/null
+++ b/dev-ruby/io-console/io-console-0.6.0-r1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby30 ruby31 ruby32"
+
+RUBY_FAKEGEM_EXTENSIONS=(ext/io/console/extconf.rb)
+RUBY_FAKEGEM_EXTENSION_LIBDIR="lib/io"
+RUBY_FAKEGEM_EXTRADOC="README.md"
+RUBY_FAKEGEM_GEMSPEC="io-console.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="add console capabilities to IO instances"
+HOMEPAGE="https://github.com/ruby/io-console"
+SRC_URI="https://github.com/ruby/io-console/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE=""
+
+all_ruby_prepare() {
+	sed -e 's/__FILE__/"'${RUBY_FAKEGEM_GEMSPEC}'"/' \
+		-e 's/git ls-files -z/find * -print0/' \
+		-i ${RUBY_FAKEGEM_GEMSPEC} || die
+	sed -e '/task :test/ s:^:#:' -i Rakefile || die
+
+	# Avoid test that require a proper TTY
+	sed -e '/test_\(bad_keyword\|failed_path\)/aomit "requires TTY"' \
+		-i test/io/console/test_io_console.rb || die
+
+	# Remove ruby and ffi files in accordance with the gemspec. These
+	# are only used when using a different ruby engine like jruby.
+	rm -fr lib/io/console.rb lib/io/console/ffi || die
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib:.:test:test/lib -rhelper -e 'Dir["test/**/test_*.rb"].each{|f| require f}' || die
+}
-- 
cgit v1.2.3