From a41f630aea0b4b71a6c9a088571f1eaaf8413d53 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 30 Oct 2022 09:03:01 +0000
Subject: gentoo auto-resync : 30:10:2022 - 09:03:01

---
 dev-ruby/hoe/hoe-3.26.0.ebuild | 52 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 dev-ruby/hoe/hoe-3.26.0.ebuild

(limited to 'dev-ruby/hoe/hoe-3.26.0.ebuild')

diff --git a/dev-ruby/hoe/hoe-3.26.0.ebuild b/dev-ruby/hoe/hoe-3.26.0.ebuild
new file mode 100644
index 000000000000..8412695175a7
--- /dev/null
+++ b/dev-ruby/hoe/hoe-3.26.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby27 ruby30 ruby31"
+
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="History.rdoc Manifest.txt README.rdoc"
+
+RUBY_FAKEGEM_EXTRAINSTALL="template"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Hoe extends rake to provide full project automation"
+HOMEPAGE="https://www.zenspider.com/projects/hoe.html"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc"
+
+ruby_add_bdepend "test? ( >=dev-ruby/minitest-5.9:5 )"
+
+ruby_add_rdepend ">=dev-ruby/rake-0.8.7 <dev-ruby/rake-15.0"
+
+all_ruby_prepare() {
+	# Skip isolation
+	sed -i -e '/isolate/ s:^:#:' Rakefile || die
+
+	# Skip test depending on specifics of gem command name
+	sed -i -e '/test_nosudo/,/^  end/ s:^:#:' test/test_hoe.rb || die
+
+	# Avoid test with random sort order
+	sed -i -e '/test_possibly_better/askip "ordering issues"' test/test_hoe.rb || die
+
+	# Avoid test that depends on specifics of merged packages
+	sed -i -e '/test_make_rdoc_cmd/askip "dependent on merged packages"' test/test_hoe_publish.rb || die
+}
+
+all_ruby_compile() {
+	all_fakegem_compile
+
+	if use doc; then
+		rdoc --title "seattlerb's hoe-${PV} Documentation" -o doc --main README.txt lib History.txt Manifest.txt README.txt || die
+		rm -f doc/js/*.gz || die
+	fi
+}
+
+each_ruby_test() {
+	export -n A
+	each_fakegem_test
+}
-- 
cgit v1.2.3