From 77f1c17f5328e59f3991203c579fbc85df6898a0 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 5 Jun 2023 09:36:29 +0100
Subject: gentoo auto-resync : 05:06:2023 - 09:36:29

---
 dev-ruby/gruff/gruff-0.21.0.ebuild | 53 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-ruby/gruff/gruff-0.21.0.ebuild

(limited to 'dev-ruby/gruff/gruff-0.21.0.ebuild')

diff --git a/dev-ruby/gruff/gruff-0.21.0.ebuild b/dev-ruby/gruff/gruff-0.21.0.ebuild
new file mode 100644
index 000000000000..8474accf9636
--- /dev/null
+++ b/dev-ruby/gruff/gruff-0.21.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby30 ruby31 ruby32"
+
+RUBY_FAKEGEM_TASK_DOC=""
+
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_EXTRAINSTALL="assets rails_generators"
+
+RUBY_FAKEGEM_GEMSPEC="gruff.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Beautiful graphs for one or multiple datasets"
+HOMEPAGE="https://github.com/topfunky/gruff"
+SRC_URI="https://github.com/topfunky/gruff/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+# imagemagick is an indirect dependency through rmagick. However, for
+# gruff to work properly imagemagick needs to be compiled with truetype
+# support and this cannot be expressed in the rmagick dependency. Tests
+# also require imagemagick to have jpeg and png support.
+DEPEND="${DEPEND} test? ( media-gfx/imagemagick[jpeg,png,truetype,webp] )"
+RDEPEND="${RDEPEND} media-gfx/imagemagick[truetype]"
+
+ruby_add_rdepend "dev-ruby/histogram >=dev-ruby/rmagick-4.2:*"
+ruby_add_bdepend "
+	test? (
+		dev-ruby/test-unit
+	)"
+
+all_ruby_prepare() {
+	sed -i -e '/\(reporters\|simplecov\)/I s:^:#:' test/gruff_test_case.rb || die
+	sed -i -e '2irequire "date"' test/test_scatter.rb || die
+
+	sed -e 's/git ls-files/find . -print/' \
+		-i ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+each_ruby_test() {
+	# Skip the image comparison checks since the images are not
+	# pixel-perfect identical, most likely due to the use of a slightly
+	# different font.
+	SKIP_CHECK=true ${RUBY} -Ilib:. -e "Dir['test/test_*.rb'].each{|f| require f}" || die
+}
-- 
cgit v1.2.3