From 93a93e9a3b53c1a73142a305ea1f8136846942ee Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 22 Dec 2021 14:08:05 +0000
Subject: gentoo resync : 22.12.2021

---
 dev-ros/roslaunch/roslaunch-1.15.13.ebuild | 62 ++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 dev-ros/roslaunch/roslaunch-1.15.13.ebuild

(limited to 'dev-ros/roslaunch/roslaunch-1.15.13.ebuild')

diff --git a/dev-ros/roslaunch/roslaunch-1.15.13.ebuild b/dev-ros/roslaunch/roslaunch-1.15.13.ebuild
new file mode 100644
index 000000000000..2cc8912dd83a
--- /dev/null
+++ b/dev-ros/roslaunch/roslaunch-1.15.13.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ROS_REPO_URI="https://github.com/ros/ros_comm"
+KEYWORDS="~amd64 ~arm"
+ROS_SUBDIR=tools/${PN}
+
+inherit ros-catkin
+
+DESCRIPTION="Tool for easily launching multiple ROS nodes"
+LICENSE="BSD"
+SLOT="0"
+
+CDEPEND="
+	dev-ros/roslib[${PYTHON_SINGLE_USEDEP}]
+	$(python_gen_cond_dep "dev-python/rospkg[\${PYTHON_USEDEP}]")
+	dev-ros/rosclean[${PYTHON_SINGLE_USEDEP}]
+	$(python_gen_cond_dep "dev-python/pyyaml[\${PYTHON_USEDEP}]")
+	dev-ros/rosgraph_msgs[${CATKIN_MESSAGES_PYTHON_USEDEP}]
+	dev-ros/rosparam[${PYTHON_SINGLE_USEDEP}]
+	dev-ros/rosmaster[${PYTHON_SINGLE_USEDEP}]
+	dev-ros/rosout
+"
+
+RDEPEND="
+	${CDEPEND}
+	acct-group/ros
+	acct-user/ros
+"
+DEPEND="
+	${CDEPEND}
+	test? (
+		$(python_gen_cond_dep "dev-util/rosdep[\${PYTHON_USEDEP}]")
+		$(python_gen_cond_dep "dev-python/nose[\${PYTHON_USEDEP}]")
+		dev-ros/test_rosmaster
+	)"
+
+src_test() {
+	export ROS_PACKAGE_PATH="${S}:${S}/../rosmaster/:${EPREFIX}/usr/share/ros_packages/rosparam:${EPREFIX}/usr/share/ros_packages/roslib:${EPREFIX}/usr/share/ros_packages/rosout"
+	ros-catkin_src_test
+}
+
+src_install() {
+	ros-catkin_src_install
+
+	dodir /etc/ros
+	sed -e "s/@PKG_VERSION@/${PV}/" "${FILESDIR}/roscore.xml.in" > "${ED}/etc/ros/roscore.xml" || die
+
+	newinitd "${FILESDIR}/roscore.initd" roscore
+	newconfd "${FILESDIR}/roscore.confd" roscore
+
+	newinitd "${FILESDIR}/roslaunch.initd" roslaunch
+	newconfd "${FILESDIR}/roslaunch.confd" roslaunch
+
+	doenvd "${FILESDIR}/40roslaunch"
+
+	# Needed by test_roslaunch
+	insinto /usr/share/${PN}
+	doins test/xml/noop.launch
+}
-- 
cgit v1.2.3