From b1c81de4fadbd00897700a7321f03b390d952b2e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Thu, 26 Aug 2021 00:09:36 +0100
Subject: gentoo resync : 26.08.2021

---
 dev-qt/qtwidgets/qtwidgets-5.15.2-r1.ebuild | 62 +++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 dev-qt/qtwidgets/qtwidgets-5.15.2-r1.ebuild

(limited to 'dev-qt/qtwidgets/qtwidgets-5.15.2-r1.ebuild')

diff --git a/dev-qt/qtwidgets/qtwidgets-5.15.2-r1.ebuild b/dev-qt/qtwidgets/qtwidgets-5.15.2-r1.ebuild
new file mode 100644
index 000000000000..3332a278e385
--- /dev/null
+++ b/dev-qt/qtwidgets/qtwidgets-5.15.2-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Set of components for creating classic desktop-style UIs for the Qt5 framework"
+SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/qtbase-${PV}-gcc11.patch.xz"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="amd64 arm arm64 ~hppa ppc ppc64 ~riscv ~sparc x86"
+fi
+
+# keep IUSE defaults in sync with qtgui
+IUSE="gles2-only gtk +png +X"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}:5=
+	~dev-qt/qtgui-${PV}[gles2-only=,png=,X?]
+	gtk? (
+		~dev-qt/qtgui-${PV}[dbus]
+		x11-libs/gtk+:3
+		x11-libs/libX11
+		x11-libs/pango
+	)
+"
+RDEPEND="${DEPEND}
+	dev-qt/qtchooser
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/tools/uic
+	src/widgets
+	src/plugins/platformthemes
+)
+
+QT5_GENTOO_CONFIG=(
+	gtk:gtk3:
+	::widgets
+	!:no-widgets:
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:widgets
+)
+
+PATCHES=( "${WORKDIR}/qtbase-${PV}-gcc11.patch" ) # bug 752012
+
+src_configure() {
+	local myconf=(
+		-opengl $(usex gles2-only es2 desktop)
+		$(qt_use gtk)
+		-gui
+		$(qt_use png libpng system)
+		-widgets
+		$(qt_use X xcb)
+		$(usex X '-xcb-xlib -xkbcommon' '')
+	)
+	qt5-build_src_configure
+}
-- 
cgit v1.2.3