From 418459f7de9eb29d6db8b61681f39c467d9600e1 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 8 Oct 2023 18:03:40 +0100
Subject: gentoo auto-resync : 08:10:2023 - 18:03:40

---
 dev-qt/qtwayland/qtwayland-5.15.11.ebuild | 51 +++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 dev-qt/qtwayland/qtwayland-5.15.11.ebuild

(limited to 'dev-qt/qtwayland/qtwayland-5.15.11.ebuild')

diff --git a/dev-qt/qtwayland/qtwayland-5.15.11.ebuild b/dev-qt/qtwayland/qtwayland-5.15.11.ebuild
new file mode 100644
index 000000000000..57fced440a1c
--- /dev/null
+++ b/dev-qt/qtwayland/qtwayland-5.15.11.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} != *9999* ]]; then
+	QT5_KDEPATCHSET_REV=1
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+inherit qt5-build
+
+DESCRIPTION="Wayland platform plugin for Qt"
+
+SLOT=5/${QT5_PV} # bug 815646
+IUSE="compositor"
+
+RDEPEND="
+	dev-libs/wayland
+	=dev-qt/qtcore-${QT5_PV}*:5=
+	=dev-qt/qtgui-${QT5_PV}*:5=[egl,libinput]
+	media-libs/libglvnd
+	x11-libs/libxkbcommon
+	compositor? (
+		=dev-qt/qtdeclarative-${QT5_PV}*:5=
+		=dev-qt/qtgui-${QT5_PV}*:5=[vulkan]
+	)
+"
+DEPEND="${RDEPEND}
+	compositor? ( dev-util/vulkan-headers )
+"
+BDEPEND="dev-util/wayland-scanner"
+
+src_configure() {
+	local myqmakeargs=(
+		--
+		-no-feature-xcomposite-egl
+		-no-feature-xcomposite-glx
+		$(qt_use compositor feature-wayland-server)
+		$(qt_use compositor feature-wayland-dmabuf-server-buffer)
+		$(qt_use compositor feature-wayland-drm-egl-server-buffer)
+		$(qt_use compositor feature-wayland-shm-emulation-server-buffer)
+		$(qt_use compositor feature-wayland-vulkan-server-buffer)
+	)
+	qt5-build_src_configure
+}
+
+src_install() {
+	qt5-build_src_install
+	rm "${D}${QT5_BINDIR}"/qtwaylandscanner || die
+}
-- 
cgit v1.2.3