From 44a22ab89258383202cae3037c3a5685aa903251 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 5 Sep 2023 16:23:54 +0100
Subject: gentoo auto-resync : 05:09:2023 - 16:23:54

---
 dev-qt/qtspeech/qtspeech-6.5.2.ebuild | 48 +++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 dev-qt/qtspeech/qtspeech-6.5.2.ebuild

(limited to 'dev-qt/qtspeech/qtspeech-6.5.2.ebuild')

diff --git a/dev-qt/qtspeech/qtspeech-6.5.2.ebuild b/dev-qt/qtspeech/qtspeech-6.5.2.ebuild
new file mode 100644
index 000000000000..94803ab4eff3
--- /dev/null
+++ b/dev-qt/qtspeech/qtspeech-6.5.2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Text-to-speech library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+IUSE="flite +speechd"
+# can build with neither, but then it is just mock tts and may be confusing
+REQUIRED_USE="|| ( flite speechd )"
+
+# TODO: tests are known failing with clang and needs looking into, albeit
+# it is still usable at runtime save for applications segfaulting on exit
+# similarly to QTBUG-90626 (not that this has in-tree revdeps as of writing
+# of this). Restricting because also seen this result in hanging. Note that
+# qtspeech:6 is still somewhat new (started in 6.4.0), and should review
+# status on new major versions.
+RESTRICT="test"
+
+RDEPEND="
+	~dev-qt/qtbase-${PV}:6
+	~dev-qt/qtdeclarative-${PV}:6
+	flite? (
+		app-accessibility/flite
+		~dev-qt/qtmultimedia-${PV}:6
+	)
+	speechd? ( app-accessibility/speech-dispatcher )
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(qt_feature flite)
+		$(qt_feature speechd)
+
+		# flite_alsa was likely to work around old issues in flite, it does
+		# nothing but add -lasound (no code change, and is unneeded)
+		-DQT_FEATURE_flite_alsa=OFF
+	)
+
+	qt6-build_src_configure
+}
-- 
cgit v1.2.3