From b1c81de4fadbd00897700a7321f03b390d952b2e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Thu, 26 Aug 2021 00:09:36 +0100
Subject: gentoo resync : 26.08.2021

---
 .../qtprintsupport/qtprintsupport-5.15.2-r1.ebuild | 46 ++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 dev-qt/qtprintsupport/qtprintsupport-5.15.2-r1.ebuild

(limited to 'dev-qt/qtprintsupport/qtprintsupport-5.15.2-r1.ebuild')

diff --git a/dev-qt/qtprintsupport/qtprintsupport-5.15.2-r1.ebuild b/dev-qt/qtprintsupport/qtprintsupport-5.15.2-r1.ebuild
new file mode 100644
index 000000000000..6442c1d07e48
--- /dev/null
+++ b/dev-qt/qtprintsupport/qtprintsupport-5.15.2-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+QT5_MODULE="qtbase"
+VIRTUALX_REQUIRED="test"
+inherit qt5-build
+
+DESCRIPTION="Printing support library for the Qt5 framework"
+SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/qtbase-${PV}-gcc11.patch.xz"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="amd64 arm arm64 ~hppa ppc ppc64 ~riscv ~sparc x86"
+fi
+
+IUSE="cups gles2-only"
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}:5=
+	~dev-qt/qtgui-${PV}[gles2-only=]
+	~dev-qt/qtwidgets-${PV}[gles2-only=]
+	cups? ( >=net-print/cups-1.4 )
+"
+DEPEND="${RDEPEND}
+	test? ( ~dev-qt/qtnetwork-${PV} )
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/printsupport
+	src/plugins/printsupport
+)
+
+QT5_GENTOO_CONFIG=(
+	cups
+)
+
+PATCHES=( "${WORKDIR}/qtbase-${PV}-gcc11.patch" ) # bug 752012
+
+src_configure() {
+	local myconf=(
+		$(qt_use cups)
+		-opengl $(usex gles2-only es2 desktop)
+	)
+	qt5-build_src_configure
+}
-- 
cgit v1.2.3