From db70871b2044b9bfde346d6f4027dafb0a013c4c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 15 Jun 2023 13:38:09 +0100
Subject: gentoo auto-resync : 15:06:2023 - 13:38:09

---
 dev-qt/qtmultimedia/qtmultimedia-5.15.10.ebuild | 70 +++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 dev-qt/qtmultimedia/qtmultimedia-5.15.10.ebuild

(limited to 'dev-qt/qtmultimedia/qtmultimedia-5.15.10.ebuild')

diff --git a/dev-qt/qtmultimedia/qtmultimedia-5.15.10.ebuild b/dev-qt/qtmultimedia/qtmultimedia-5.15.10.ebuild
new file mode 100644
index 000000000000..54a0996459c5
--- /dev/null
+++ b/dev-qt/qtmultimedia/qtmultimedia-5.15.10.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} != *9999* ]]; then
+	QT5_KDEPATCHSET_REV=1
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+inherit qt5-build
+
+DESCRIPTION="Multimedia (audio, video, radio, camera) library for the Qt5 framework"
+
+IUSE="alsa gles2-only gstreamer openal pulseaudio qml widgets"
+
+RDEPEND="
+	=dev-qt/qtcore-${QT5_PV}*
+	=dev-qt/qtgui-${QT5_PV}*[gles2-only=]
+	=dev-qt/qtnetwork-${QT5_PV}*
+	alsa? ( media-libs/alsa-lib )
+	gstreamer? (
+		dev-libs/glib:2
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-bad:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	pulseaudio? ( media-libs/libpulse[glib] )
+	qml? (
+		=dev-qt/qtdeclarative-${QT5_PV}*
+		gles2-only? ( =dev-qt/qtgui-${QT5_PV}*[egl] )
+		openal? ( media-libs/openal )
+	)
+	widgets? (
+		=dev-qt/qtwidgets-${QT5_PV}*[gles2-only=]
+		media-libs/libglvnd
+	)
+"
+DEPEND="${RDEPEND}
+	gstreamer? ( x11-base/xorg-proto )
+"
+
+src_prepare() {
+	sed -i -e '/CONFIG\s*+=/ s/optimize_full//' \
+		src/multimedia/multimedia.pro || die
+
+	qt_use_disable_config openal openal \
+		src/imports/imports.pro
+
+	qt_use_disable_mod qml quick \
+		src/src.pro \
+		src/plugins/plugins.pro
+
+	qt_use_disable_mod widgets widgets \
+		src/src.pro \
+		src/gsttools/gsttools.pro \
+		src/plugins/gstreamer/common.pri
+
+	qt5-build_src_prepare
+}
+
+src_configure() {
+	local myqmakeargs=(
+		--
+		$(qt_use alsa)
+		$(qt_use gstreamer)
+		$(qt_use pulseaudio)
+	)
+	qt5-build_src_configure
+}
-- 
cgit v1.2.3