From 99abbc5e5a6ecd3fc981b45646fd8cb5d320377b Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 24 Feb 2018 19:58:07 +0000
Subject: gentoo resync : 24.02.2018

---
 .../qtlockedfile-2.4.1_p20171024.ebuild            | 52 ++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 dev-qt/qtlockedfile/qtlockedfile-2.4.1_p20171024.ebuild

(limited to 'dev-qt/qtlockedfile/qtlockedfile-2.4.1_p20171024.ebuild')

diff --git a/dev-qt/qtlockedfile/qtlockedfile-2.4.1_p20171024.ebuild b/dev-qt/qtlockedfile/qtlockedfile-2.4.1_p20171024.ebuild
new file mode 100644
index 000000000000..cfa7ba1b31d9
--- /dev/null
+++ b/dev-qt/qtlockedfile/qtlockedfile-2.4.1_p20171024.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit qmake-utils
+
+MY_P=qt-solutions-${PV#*_p}
+
+DESCRIPTION="QFile extension with advisory locking functions"
+HOMEPAGE="https://code.qt.io/cgit/qt-solutions/qt-solutions.git/"
+SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.xz"
+
+LICENSE="|| ( LGPL-2.1 GPL-3 )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
+IUSE="doc"
+
+DEPEND="dev-qt/qtcore:5"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}/${PN}"
+
+src_prepare() {
+	default
+
+	echo 'SOLUTIONS_LIBRARY = yes' > config.pri
+	echo 'QT -= gui' >> src/qtlockedfile.pri
+
+	sed -i -e "s/-head/-${PV%.*}/" common.pri || die
+	sed -i -e '/SUBDIRS+=example/d' ${PN}.pro || die
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( doc/html/. )
+	einstalldocs
+
+	# libraries
+	dolib.so lib/*
+
+	# headers
+	insinto "$(qt5_get_headerdir)"/QtSolutions
+	doins src/QtLockedFile src/${PN}.h
+
+	# .prf files
+	insinto "$(qt5_get_mkspecsdir)"/features
+	doins "${FILESDIR}"/${PN}.prf
+}
-- 
cgit v1.2.3