From 56e9cc62c11546e2c081f8dc14a9cc965f14787c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 10 Aug 2023 15:32:41 +0100
Subject: gentoo auto-resync : 10:08:2023 - 15:32:40

---
 dev-python/tqdm/tqdm-4.66.1.ebuild | 45 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 dev-python/tqdm/tqdm-4.66.1.ebuild

(limited to 'dev-python/tqdm/tqdm-4.66.1.ebuild')

diff --git a/dev-python/tqdm/tqdm-4.66.1.ebuild b/dev-python/tqdm/tqdm-4.66.1.ebuild
new file mode 100644
index 000000000000..0472066fc4d2
--- /dev/null
+++ b/dev-python/tqdm/tqdm-4.66.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit bash-completion-r1 distutils-r1 pypi
+
+DESCRIPTION="Add a progress meter to your loops in a second"
+HOMEPAGE="
+	https://github.com/tqdm/tqdm/
+	https://pypi.org/project/tqdm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+IUSE="examples"
+
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# Skip unpredictable performance tests
+	tests/tests_perf.py
+)
+
+python_install_all() {
+	doman tqdm/tqdm.1
+	newbashcomp tqdm/completion.sh tqdm
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3