From f616ce4660c92a3fcb4f05663c2ab47c9defa0c3 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 30 Nov 2022 01:22:10 +0000
Subject: gentoo auto-resync : 30:11:2022 - 01:22:10

---
 dev-python/sphobjinv/sphobjinv-2.3.1.ebuild | 59 +++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 dev-python/sphobjinv/sphobjinv-2.3.1.ebuild

(limited to 'dev-python/sphobjinv/sphobjinv-2.3.1.ebuild')

diff --git a/dev-python/sphobjinv/sphobjinv-2.3.1.ebuild b/dev-python/sphobjinv/sphobjinv-2.3.1.ebuild
new file mode 100644
index 000000000000..4dcbce04a46a
--- /dev/null
+++ b/dev-python/sphobjinv/sphobjinv-2.3.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Sphinx objects.inv Inspection/Manipulation Tool"
+HOMEPAGE="
+	https://github.com/bskinn/sphobjinv/
+	https://pypi.org/project/sphobjinv/
+"
+SRC_URI="
+	https://github.com/bskinn/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/attrs-19.2[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/fuzzywuzzy[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/dictdiffer[${PYTHON_USEDEP}]
+		dev-python/pytest-check[${PYTHON_USEDEP}]
+		dev-python/pytest-ordering[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		>=dev-python/stdio-mgr-1.0.1[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/timeout-decorator[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Internet
+	README.rst::README.rst
+	tests/test_readme.py::test_readme_shell_cmds
+)
+
+src_prepare() {
+	sed -e '/CLI_TEST_TIMEOUT/s/2/20/' -i tests/test_cli.py || die
+
+	# remove bundled deps
+	rm -r src/sphobjinv/_vendored || die
+	sed -i -e 's:sphobjinv[.]_vendored[.]::' src/sphobjinv/*.py || die
+
+	distutils-r1_src_prepare
+}
-- 
cgit v1.2.3