From 7c9730bcb62df7cbf8248c5db9a478aac52c60ea Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 17 Feb 2023 14:07:47 +0000
Subject: gentoo auto-resync : 17:02:2023 - 14:07:46

---
 .../requests-ntlm/requests-ntlm-1.2.0.ebuild       | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-python/requests-ntlm/requests-ntlm-1.2.0.ebuild

(limited to 'dev-python/requests-ntlm/requests-ntlm-1.2.0.ebuild')

diff --git a/dev-python/requests-ntlm/requests-ntlm-1.2.0.ebuild b/dev-python/requests-ntlm/requests-ntlm-1.2.0.ebuild
new file mode 100644
index 000000000000..81473a0deacb
--- /dev/null
+++ b/dev-python/requests-ntlm/requests-ntlm-1.2.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="HTTP NTLM authentication using the requests library"
+HOMEPAGE="
+	https://github.com/requests/requests-ntlm/
+	https://pypi.org/project/requests-ntlm/
+"
+SRC_URI="
+	https://github.com/requests/requests-ntlm/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+SLOT="0"
+LICENSE="ISC"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/cryptography-1.3[${PYTHON_USEDEP}]
+	>=dev-python/pyspnego-0.1.6[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.0.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/flask[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local ts_pid test_ret
+
+	"${EPYTHON}" -m tests.test_server &> "${T}"/test-server.log &
+	ts_pid=${!}
+
+	nonfatal epytest tests/unit
+	test_ret=${?}
+
+	kill "${ts_pid}"
+	[[ ${test_ret} -ne 0 ]] && die "Tests failed with ${EPYTHON}"
+}
-- 
cgit v1.2.3