From e2db47eaae00ec33f8971db44b68645c5d3b9590 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 17 Aug 2021 11:36:49 +0100
Subject: gentoo resync : 17.08.2021

---
 .../requests-cache/requests-cache-0.7.4.ebuild     | 54 ++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 dev-python/requests-cache/requests-cache-0.7.4.ebuild

(limited to 'dev-python/requests-cache/requests-cache-0.7.4.ebuild')

diff --git a/dev-python/requests-cache/requests-cache-0.7.4.ebuild b/dev-python/requests-cache/requests-cache-0.7.4.ebuild
new file mode 100644
index 000000000000..b3e59acf4577
--- /dev/null
+++ b/dev-python/requests-cache/requests-cache-0.7.4.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=pyproject.toml
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+HOMEPAGE="
+	https://pypi.org/project/requests-cache/
+	https://github.com/reclosedev/requests-cache/"
+DESCRIPTION="Persistent cache for requests library"
+SRC_URI="
+	https://github.com/reclosedev/requests-cache/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/cattrs[${PYTHON_USEDEP}]
+	dev-python/itsdangerous[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/url-normalize-1.4[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		dev-python/timeout-decorator[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local ignore=(
+		# These require extra servers running
+		tests/integration/test_dynamodb.py
+		tests/integration/test_gridfs.py
+		tests/integration/test_mongodb.py
+		tests/integration/test_redis.py
+	)
+	local deselect=(
+		# Requires Internet access
+		tests/integration/test_compat.py::test_version_upgrade
+	)
+
+	local -x USE_PYTEST_HTTPBIN=true
+	epytest ${deselect[@]/#/--deselect } ${ignore[@]/#/--ignore }
+}
-- 
cgit v1.2.3