From 8e95bde8579d855189ccca3e693b4e3792f136c2 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 11 Dec 2023 23:23:25 +0000
Subject: gentoo auto-resync : 11:12:2023 - 23:23:25

---
 dev-python/reportlab/reportlab-4.0.8.ebuild | 53 +++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-python/reportlab/reportlab-4.0.8.ebuild

(limited to 'dev-python/reportlab/reportlab-4.0.8.ebuild')

diff --git a/dev-python/reportlab/reportlab-4.0.8.ebuild b/dev-python/reportlab/reportlab-4.0.8.ebuild
new file mode 100644
index 000000000000..cd4a2c574b49
--- /dev/null
+++ b/dev-python/reportlab/reportlab-4.0.8.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Tools for generating printable PDF documents from any data source"
+HOMEPAGE="
+	https://www.reportlab.com/
+	https://pypi.org/project/reportlab/
+"
+SRC_URI+="
+	https://www.reportlab.com/ftp/fonts/pfbfer-20070710.zip
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/pillow[tiff,truetype,jpeg(+),${PYTHON_USEDEP}]
+"
+BDEPEND="
+	app-arch/unzip
+"
+
+distutils_enable_sphinx docs/source
+
+src_unpack() {
+	unpack ${P}.tar.gz
+	cd ${P}/src/reportlab/fonts || die
+	unpack pfbfer-20070710.zip
+}
+
+src_configure() {
+	cat > local-setup.cfg <<-EOF || die
+		[OPTIONS]
+		no-download-t1-files = 1
+	EOF
+}
+
+python_test() {
+	pushd tests >/dev/null || die
+	"${EPYTHON}" runAll.py --post-install --verbosity=2 ||
+		die "Testing failed with ${EPYTHON}"
+	popd >/dev/null || die
+}
-- 
cgit v1.2.3