From feb0daf81d888e9160f9f94502de09b66f2a63fd Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 21 Jun 2020 17:50:24 +0100
Subject: gentoo resync : 21.06.2020

---
 dev-python/rdflib/rdflib-5.0.0.ebuild | 48 +++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 dev-python/rdflib/rdflib-5.0.0.ebuild

(limited to 'dev-python/rdflib/rdflib-5.0.0.ebuild')

diff --git a/dev-python/rdflib/rdflib-5.0.0.ebuild b/dev-python/rdflib/rdflib-5.0.0.ebuild
new file mode 100644
index 000000000000..ee3a9c338a1e
--- /dev/null
+++ b/dev-python/rdflib/rdflib-5.0.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6..9} )
+PYTHON_REQ_USE="sqlite?,threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="RDF library containing a triple store and parser/serializer"
+HOMEPAGE="https://github.com/RDFLib/rdflib https://pypi.org/project/rdflib/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="berkdb examples sqlite"
+
+RDEPEND="
+	dev-python/isodate[${PYTHON_USEDEP}]
+	dev-python/html5lib[${PYTHON_USEDEP}]
+	dev-python/pyparsing[${PYTHON_USEDEP}]
+	berkdb? ( dev-python/bsddb3[${PYTHON_USEDEP}] )"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/requests[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# these tests require internet access
+	sed -i -e '/doctest/d' setup.cfg || die
+	rm test/test_sparql_service.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
-- 
cgit v1.2.3