From cf7630078a53ff74b245b148bd722994068e28f9 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 28 Oct 2022 15:59:37 +0100
Subject: gentoo auto-resync : 28:10:2022 - 15:59:37

---
 dev-python/pythran/pythran-0.12.0-r2.ebuild | 66 +++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 dev-python/pythran/pythran-0.12.0-r2.ebuild

(limited to 'dev-python/pythran/pythran-0.12.0-r2.ebuild')

diff --git a/dev-python/pythran/pythran-0.12.0-r2.ebuild b/dev-python/pythran/pythran-0.12.0-r2.ebuild
new file mode 100644
index 000000000000..3a8d913b453c
--- /dev/null
+++ b/dev-python/pythran/pythran-0.12.0-r2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_TESTED=( python3_{8..10} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" python3_11 )
+
+inherit distutils-r1 multiprocessing
+
+MY_P=${P/_p/.post}
+DESCRIPTION="Ahead of Time compiler for numeric kernels"
+HOMEPAGE="
+	https://pypi.org/project/pythran/
+	https://github.com/serge-sans-paille/pythran/
+"
+SRC_URI="
+	https://github.com/serge-sans-paille/pythran/archive/${PV/_p/.post}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~x86"
+
+RDEPEND="
+	dev-libs/boost
+	=dev-python/beniget-0.4*[${PYTHON_USEDEP}]
+	=dev-python/gast-0.5*[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/ply-3.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/ipython[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+		virtual/cblas
+		!!dev-python/setuptools-declarative-requirements
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.10.0-tests-werror.patch
+	"${FILESDIR}"/${PN}-0.12.0-gcc13.patch
+)
+
+src_configure() {
+	# TODO: package xsimd then set no_xsimd = True
+	cat >> setup.cfg <<-EOF
+	[build_py]
+	no_boost = True
+	EOF
+}
+
+python_test() {
+	local -x COLUMNS=80
+	epytest -n "$(makeopts_jobs)"
+}
-- 
cgit v1.2.3