From cb9a501c2ed1312c376917c1cbfc79542d799806 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 18 Oct 2022 13:56:32 +0100
Subject: gentoo auto-resync : 18:10:2022 - 13:56:32

---
 .../pytest-twisted/pytest-twisted-1.14.0.ebuild    | 51 ++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 dev-python/pytest-twisted/pytest-twisted-1.14.0.ebuild

(limited to 'dev-python/pytest-twisted/pytest-twisted-1.14.0.ebuild')

diff --git a/dev-python/pytest-twisted/pytest-twisted-1.14.0.ebuild b/dev-python/pytest-twisted/pytest-twisted-1.14.0.ebuild
new file mode 100644
index 000000000000..cb6ee5309a59
--- /dev/null
+++ b/dev-python/pytest-twisted/pytest-twisted-1.14.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="A pytest plugin for testing Twisted framework consumers"
+HOMEPAGE="
+	https://github.com/pytest-dev/pytest-twisted/
+	https://pypi.org/project/pytest-twisted/
+"
+SRC_URI="
+	https://github.com/pytest-dev/pytest-twisted/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~riscv ~x86"
+
+RDEPEND="
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/greenlet[${PYTHON_USEDEP}]
+	>=dev-python/pytest-2.3[${PYTHON_USEDEP}]
+	dev-python/twisted[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# If we let pytest-twisted autoload everywhere, it breaks tests in
+	# packages that don't expect it. Apply a similar hack as for bug
+	# #661218.
+	sed -e 's/"pytest11": \[[^]]*\]//' -i setup.py || die
+
+	# https://github.com/pytest-dev/pytest/issues/9280
+	sed -e '/^pytest_plugins =/d' -i testing/conftest.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_twisted
+
+	epytest -p pytester
+}
-- 
cgit v1.2.3