From 399fa07bfac673a8846466b16c76549e329b55b8 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 20 May 2023 10:17:50 +0100
Subject: gentoo auto-resync : 20:05:2023 - 10:17:50

---
 .../pytest-testinfra/pytest-testinfra-8.0.0.ebuild | 56 ++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 dev-python/pytest-testinfra/pytest-testinfra-8.0.0.ebuild

(limited to 'dev-python/pytest-testinfra/pytest-testinfra-8.0.0.ebuild')

diff --git a/dev-python/pytest-testinfra/pytest-testinfra-8.0.0.ebuild b/dev-python/pytest-testinfra/pytest-testinfra-8.0.0.ebuild
new file mode 100644
index 000000000000..ac3689c80baf
--- /dev/null
+++ b/dev-python/pytest-testinfra/pytest-testinfra-8.0.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Write unit tests in Python to test actual state of your servers"
+HOMEPAGE="
+	https://github.com/pytest-dev/pytest-testinfra/
+	https://pypi.org/project/pytest-testinfra/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+
+RDEPEND="
+	dev-python/pytest[${PYTHON_USEDEP}]
+"
+# Ansible is called via its CLI
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		app-admin/ansible
+		$(python_gen_cond_dep '
+			app-admin/salt[${PYTHON_USEDEP}]
+		' python3_10)
+		dev-python/paramiko[${PYTHON_USEDEP}]
+		dev-python/pywinrm[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x EPYTEST_DESELECT=()
+
+	# This is the only test which actually fails if salt cannot be imported
+	if [[ ${EPYTHON} == python3.11 ]]; then
+		EPYTEST_DESELECT+=(
+			test/test_backends.py::test_backend_importables
+		)
+	fi
+
+	epytest
+}
+
+pkg_postinst() {
+	elog "For the list of available connection back-ends and their dependencies,"
+	elog "please consult https://testinfra.readthedocs.io/en/latest/backends.html"
+}
-- 
cgit v1.2.3