From 590b9b7b03bf4651e099949e318755af7cfa81b8 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 1 Aug 2021 22:03:23 +0100
Subject: gentoo resync : 01.08.2021

---
 dev-python/pysvn/pysvn-1.9.15.ebuild | 64 ++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 dev-python/pysvn/pysvn-1.9.15.ebuild

(limited to 'dev-python/pysvn/pysvn-1.9.15.ebuild')

diff --git a/dev-python/pysvn/pysvn-1.9.15.ebuild b/dev-python/pysvn/pysvn-1.9.15.ebuild
new file mode 100644
index 000000000000..9e8fecfbe0e4
--- /dev/null
+++ b/dev-python/pysvn/pysvn-1.9.15.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+DISTUTILS_IN_SOURCE_BUILD=true
+DISTUTILS_USE_SETUPTOOLS=bdepend  # see setup.py
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="Object-oriented python bindings for subversion"
+HOMEPAGE="https://pysvn.sourceforge.io/"
+SRC_URI="mirror://sourceforge/project/pysvn/pysvn/V${PV}/${P}.tar.gz"
+
+LICENSE="Apache-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+IUSE="doc examples"
+
+DEPEND="
+	>=dev-python/pycxx-7.0.2[${PYTHON_USEDEP}]
+	>=dev-vcs/subversion-1.9"
+RDEPEND="${DEPEND}"
+
+python_prepare_all() {
+	# Don't use internal copy of dev-python/pycxx.
+	rm -r Import || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure() {
+	cd Source || die
+	# all config options from 1.7.6 are all already set
+	esetup.py configure
+}
+
+python_compile() {
+	cd Source || die
+	emake \
+		CC="$(tc-getCC)" \
+		CCC="$(tc-getCXX)"
+}
+
+python_test() {
+	cd Tests || die
+	emake
+}
+
+python_install() {
+	cd Source || die
+	python_domodule pysvn
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( Docs/. )
+	if use examples; then
+		docinto examples
+		dodoc -r Examples/Client/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3