From 01264ef95477b8c1380cd3525278c507006685ee Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 16 Feb 2024 11:36:40 +0000
Subject: gentoo auto-resync : 16:02:2024 - 11:36:40

---
 .../pyside6-tools/pyside6-tools-6.6.2.ebuild       | 76 ++++++++++++++++++++++
 1 file changed, 76 insertions(+)
 create mode 100644 dev-python/pyside6-tools/pyside6-tools-6.6.2.ebuild

(limited to 'dev-python/pyside6-tools/pyside6-tools-6.6.2.ebuild')

diff --git a/dev-python/pyside6-tools/pyside6-tools-6.6.2.ebuild b/dev-python/pyside6-tools/pyside6-tools-6.6.2.ebuild
new file mode 100644
index 000000000000..e7411d54de28
--- /dev/null
+++ b/dev-python/pyside6-tools/pyside6-tools-6.6.2.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# TODO: Add PyPy once officially supported. See also:
+#     https://bugreports.qt.io/browse/PYSIDE-535
+PYTHON_COMPAT=( python3_{10..12} )
+
+LLVM_COMPAT=( {15..17} )
+
+inherit cmake llvm-r1 python-r1
+
+MY_PN="pyside-setup-everywhere-src"
+
+DESCRIPTION="PySide development tools (pyside6-lupdate with support for Python)"
+HOMEPAGE="https://wiki.qt.io/PySide6"
+SRC_URI="https://download.qt.io/official_releases/QtForPython/pyside6/PySide6-${PV}-src/${MY_PN}-${PV}.tar.xz"
+S="${WORKDIR}/${MY_PN}-${PV}/sources/pyside-tools"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	~dev-python/shiboken6-${PV}[${PYTHON_USEDEP},${LLVM_USEDEP}]
+	~dev-python/pyside6-${PV}[quick,${PYTHON_USEDEP},${LLVM_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	$(llvm_gen_dep '
+		sys-devel/clang:${LLVM_SLOT}
+		sys-devel/llvm:${LLVM_SLOT}
+	')
+"
+
+src_prepare() {
+	cmake_src_prepare
+
+	python_copy_sources
+}
+
+src_configure() {
+	pyside-tools_configure() {
+		local mycmakeargs=(
+			# If this is enabled cmake just makes copies of /lib64/qt6/bin/*
+			-DNO_QT_TOOLS=yes
+		)
+		cmake_src_configure
+	}
+
+	python_foreach_impl pyside-tools_configure
+}
+
+src_compile() {
+	pyside-tools_compile() {
+		cmake_src_compile
+	}
+
+	python_foreach_impl pyside-tools_compile
+}
+
+src_install() {
+	pyside-tools_install() {
+		# This replicates the contents of the PySide6 pypi wheel
+		DESTDIR="${BUILD_DIR}" cmake_build install
+		cp __init__.py "${BUILD_DIR}/usr/bin" || die
+		rm -r  "${BUILD_DIR}/usr/bin/qtpy2cpp_lib/tests" || die
+		python_moduleinto PySide6/scripts
+		python_domodule "${BUILD_DIR}/usr/bin/."
+	}
+
+	python_foreach_impl pyside-tools_install
+
+	einstalldocs
+}
-- 
cgit v1.2.3