From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 dev-python/pyopenssl/pyopenssl-17.0.0.ebuild | 62 ++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 dev-python/pyopenssl/pyopenssl-17.0.0.ebuild

(limited to 'dev-python/pyopenssl/pyopenssl-17.0.0.ebuild')

diff --git a/dev-python/pyopenssl/pyopenssl-17.0.0.ebuild b/dev-python/pyopenssl/pyopenssl-17.0.0.ebuild
new file mode 100644
index 000000000000..ba3f71d2929a
--- /dev/null
+++ b/dev-python/pyopenssl/pyopenssl-17.0.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy{,3} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 flag-o-matic
+
+MY_PN=pyOpenSSL
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python interface to the OpenSSL library"
+HOMEPAGE="
+	http://pyopenssl.sourceforge.net/
+	https://launchpad.net/pyopenssl
+	https://pypi.python.org/pypi/pyOpenSSL
+"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x64-cygwin ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris"
+IUSE="doc examples test"
+
+RDEPEND="
+	>=dev-python/six-1.5.2[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-1.3[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		virtual/python-cffi[${PYTHON_USEDEP}]
+		>=dev-python/pytest-3.0.1[${PYTHON_USEDEP}] )"
+
+S=${WORKDIR}/${MY_P}
+
+python_prepare_all() {
+	# Requires network access
+	sed -i -e 's/test_set_default_verify_paths/_&/' tests/test_ssl.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	# FIXME: for some reason, no-ops on PyPy
+	py.test -v || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	if use examples ; then
+		docinto examples
+		dodoc -r examples/*
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3