From 7051f2e58b6bbc371b2c94cead2715bf06310adb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 11 Jan 2023 23:45:17 +0000
Subject: gentoo auto-resync : 11:01:2023 - 23:45:17

---
 .../pymdown-extensions-9.9.1.ebuild                | 59 ++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 dev-python/pymdown-extensions/pymdown-extensions-9.9.1.ebuild

(limited to 'dev-python/pymdown-extensions/pymdown-extensions-9.9.1.ebuild')

diff --git a/dev-python/pymdown-extensions/pymdown-extensions-9.9.1.ebuild b/dev-python/pymdown-extensions/pymdown-extensions-9.9.1.ebuild
new file mode 100644
index 000000000000..da6901b02502
--- /dev/null
+++ b/dev-python/pymdown-extensions/pymdown-extensions-9.9.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8..11} )
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="
+	dev-python/mkdocs-git-revision-date-localized-plugin
+	dev-python/mkdocs-minify-plugin
+	dev-python/mkdocs-material
+	dev-python/pymdown-lexers
+	dev-python/pyspelling
+"
+DOCS_INITIALIZE_GIT=1
+
+inherit distutils-r1 docs
+
+DESCRIPTION="Extensions for Python Markdown"
+HOMEPAGE="
+	https://github.com/facelessuser/pymdown-extensions/
+	https://pypi.org/project/pymdown-extensions/
+"
+SRC_URI="
+	https://github.com/facelessuser/pymdown-extensions/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/markdown-3.2[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/pygments-2.12.0[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_compile_all() {
+	default
+	# We need to do this manually instead of relying on docs_compile
+	# https://bytemeta.vip/repo/facelessuser/pymdown-extensions/issues/1446
+	# https://bugs.gentoo.org/859637
+	if use doc; then
+		python -m mkdocs build || die "Failed to make docs"
+		# Colliding files found by ecompress:
+		rm site/sitemap.xml.gz || die
+		HTML_DOCS=( "site/." )
+	fi
+}
-- 
cgit v1.2.3