From 0f558761aa2dee1017b4751e4017205e015a9560 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 29 Jun 2022 12:04:12 +0100
Subject: gentoo resync : 29.12.2022

---
 dev-python/pydevd/Manifest               |  2 +-
 dev-python/pydevd/pydevd-2.8.0-r1.ebuild | 89 ++++++++++++++++++++++++++++++++
 dev-python/pydevd/pydevd-2.8.0.ebuild    | 88 -------------------------------
 3 files changed, 90 insertions(+), 89 deletions(-)
 create mode 100644 dev-python/pydevd/pydevd-2.8.0-r1.ebuild
 delete mode 100644 dev-python/pydevd/pydevd-2.8.0.ebuild

(limited to 'dev-python/pydevd')

diff --git a/dev-python/pydevd/Manifest b/dev-python/pydevd/Manifest
index df5c21fa0085..8a071f2aff62 100644
--- a/dev-python/pydevd/Manifest
+++ b/dev-python/pydevd/Manifest
@@ -1,3 +1,3 @@
 DIST pydev_debugger_2_8_0.tar.gz 4171117 BLAKE2B 4f0ea0eeb228cb66f71e2046438396ff5ce59b42e620a067bc515ff504fa2da151e05f8ea6cf2d1aaa0768122431ccb45708a88c0616fb2859e96671b172e822 SHA512 b0189f1824b52f8ad35d1d1cfba0bd734806541ae2ff4f410c110763201630d296d10c2b7eaac8c656dfb3ff0f3c31bfdf2de28323778000cc7821e123a877d3
-EBUILD pydevd-2.8.0.ebuild 2551 BLAKE2B 9d412430efa60fe20476d45d2a13729c713dfb420db7d0cd652847ab2a151b3ab59dfc3fd80862ce1ca43e3f615d867c0ccc4bb7639dfdeb0c81c69a3b4e078a SHA512 659ce6f3a2388704f0105bb0bb77a5b49a08fb26e29cf268d50d103c500c9989cf9d2784fee980cbf4d8c202489484b7746f295f8ca6b608df4b06bab356b2e4
+EBUILD pydevd-2.8.0-r1.ebuild 2529 BLAKE2B bcdba7e5dcb16c62376134ea3bca43efb079eddde4b3a364f26937916ac7ea420db6bacddab587db30efa3cc41b6fdc05989db139e1760e3b6bdd80d63e68dd8 SHA512 8ce03313ecfb954d0c9d00c8c1efdfd94b0b0524c4fec63f84e9b2cca3fc454e9a62cdfc8a625be07baf27f40918cd5d58e5e01b673f35a795cc35b15afa01ec
 MISC metadata.xml 384 BLAKE2B 37a4caa01a28f98ec8d141129c08754e6ba4dee5910a81c26f3eafcd7ac832962e91d3e39783e4859ac7e5ae5754837c89e496c4c2c205d12626359adf7dddae SHA512 5cf80b2e0eaf21e900c83341e9bef5c74a36d3c0a7354e3b6a832184cc60c42eeef6a22236e4fd9d484dc8834e5d4f98facd2578c223da2cc187dd76f91db764
diff --git a/dev-python/pydevd/pydevd-2.8.0-r1.ebuild b/dev-python/pydevd/pydevd-2.8.0-r1.ebuild
new file mode 100644
index 000000000000..a4da1a2f06b0
--- /dev/null
+++ b/dev-python/pydevd/pydevd-2.8.0-r1.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+inherit distutils-r1 toolchain-funcs
+
+MY_P="pydev_debugger_${PV//./_}"
+
+DESCRIPTION="PyDev.Debugger (used in PyDev, PyCharm and VSCode Python)"
+HOMEPAGE="https://github.com/fabioz/PyDev.Debugger/"
+SRC_URI="https://github.com/fabioz/PyDev.Debugger/archive/${MY_P}.tar.gz"
+S="${WORKDIR}/PyDev.Debugger-${MY_P}"
+
+LICENSE="EPL-1.0"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ppc ppc64 ~riscv ~s390 sparc x86"
+
+# After removing and recompiling the prebuilt lib the tests fail?
+# For some reason the test suite is executing a slightly different gdb command
+# then before, which is lacking the file name of the lib that was pre built:
+# gdb: No symbol table is loaded. Use the "file" command
+# This also happens outside of portage so it is not related to any *FLAGS
+RESTRICT="test"
+
+BDEPEND="
+	test? (
+		dev-python/untangle[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+	)
+"
+
+# Block against the version of debugpy that still bundles pydevd
+RDEPEND="
+	!<dev-python/debugpy-1.4.2
+	sys-devel/gdb
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# Drop -O3 and -flto compiler args
+	sed -i \
+		-e 's/extra_link_args = extra_compile_args\[\:\]/pass/g' \
+		-e '/extra_compile_args/d' \
+		setup.py || die
+
+	# Clean up some prebuilt files
+	rm -r third_party || die
+	cd pydevd_attach_to_process || die
+
+	# Remove these Windows files
+	rm attach_{amd64,x86}.dll || die
+	rm inject_dll_{amd64,x86}.exe || die
+	rm run_code_on_dllmain_{amd64,x86}.dll || die
+	rm -r windows winappdbg || die
+
+	# Remove these MacOS files
+	rm attach_x86_64.dylib || die
+
+	# Remove these prebuilt linux files
+	rm attach_linux_{amd64,x86}.so || die
+
+	cd linux_and_mac || die
+	rm compile_mac.sh || die
+}
+
+src_compile() {
+	pushd pydevd_attach_to_process/linux_and_mac || die
+	# recompile removed file (extracted from compile_linux.sh)
+	$(tc-getBUILD_CXX) ${CXXFLAGS} ${CPPFLAGS} -o "attach_linux_${ARCH}.so" \
+		${LDFLAGS} -nostartfiles attach.cpp -ldl || die
+	mv "attach_linux_${ARCH}.so" ../ || die
+	popd || die
+
+	distutils-r1_src_compile
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	# Remove this duplicate that is installed directly to /usr/
+	# These files are also correctly installed to the python site-packages dir
+	rm -r "${ED}/usr/pydevd_attach_to_process" || die
+}
diff --git a/dev-python/pydevd/pydevd-2.8.0.ebuild b/dev-python/pydevd/pydevd-2.8.0.ebuild
deleted file mode 100644
index a6bc2036e653..000000000000
--- a/dev-python/pydevd/pydevd-2.8.0.ebuild
+++ /dev/null
@@ -1,88 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{8..10} )
-inherit distutils-r1 toolchain-funcs
-
-MY_P="pydev_debugger_${PV//./_}"
-
-DESCRIPTION="PyDev.Debugger (used in PyDev, PyCharm and VSCode Python)"
-HOMEPAGE="https://github.com/fabioz/PyDev.Debugger/"
-SRC_URI="https://github.com/fabioz/PyDev.Debugger/archive/${MY_P}.tar.gz"
-S="${WORKDIR}/PyDev.Debugger-${MY_P}"
-
-LICENSE="EPL-1.0"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ppc ppc64 ~riscv ~s390 sparc x86"
-
-# After removing and recompiling the prebuilt lib the tests fail?
-# For some reason the test suite is executing a slightly different gdb command
-# then before, which is lacking the file name of the lib that was pre built:
-# gdb: No symbol table is loaded. Use the "file" command
-# This also happens outside of portage so it is not related to any *FLAGS
-RESTRICT="test"
-
-BDEPEND="
-	test? (
-		dev-python/untangle[${PYTHON_USEDEP}]
-		dev-python/numpy[${PYTHON_USEDEP}]
-		dev-python/psutil[${PYTHON_USEDEP}]
-	)
-"
-
-# Block against the version of debugpy that still bundles pydevd
-RDEPEND="
-	!<dev-python/debugpy-1.4.2
-	sys-devel/gdb
-"
-
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	distutils-r1_python_prepare_all
-
-	# Drop -O3 and -flto compiler args
-	sed -i \
-		-e 's/extra_link_args = extra_compile_args\[\:\]/pass/g' \
-		-e '/extra_compile_args/d' \
-		setup.py || die
-
-	# Clean up some prebuilt files
-	rm -r third_party || die
-	cd pydevd_attach_to_process || die
-
-	# Remove these Windows files
-	rm attach_{amd64,x86}.dll || die
-	rm inject_dll_{amd64,x86}.exe || die
-	rm run_code_on_dllmain_{amd64,x86}.dll || die
-	rm -r windows winappdbg || die
-
-	# Remove these MacOS files
-	rm attach_x86_64.dylib || die
-
-	# Remove these prebuilt linux files
-	rm attach_linux_{amd64,x86}.so || die
-
-	cd linux_and_mac || die
-	rm compile_mac.sh || die
-}
-
-src_compile() {
-	pushd pydevd_attach_to_process/linux_and_mac || die
-	# recompile removed file (extracted from compile_linux.sh)
-	$(tc-getBUILD_CXX) ${CXXFLAGS} ${CPPFLAGS} -o "attach_linux_${ARCH}.so" \
-		${LDFLAGS} -nostartfiles attach.cpp -ldl || die
-	mv "attach_linux_${ARCH}.so" ../ || die
-	popd || die
-	python_foreach_impl distutils-r1_python_compile
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-	# Remove this duplicate that is installed directly to /usr/
-	# These files are also correctly installed to the python site-packages dir
-	rm -r "${ED}/usr/pydevd_attach_to_process" || die
-}
-- 
cgit v1.2.3