From d162ba1860a88062f4cd61f8b52fc303ba0b2991 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 7 Aug 2021 00:16:33 +0100
Subject: gentoo resync : 07.08.2021

---
 dev-python/pybind11/pybind11-2.7.1.ebuild | 53 +++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-python/pybind11/pybind11-2.7.1.ebuild

(limited to 'dev-python/pybind11/pybind11-2.7.1.ebuild')

diff --git a/dev-python/pybind11/pybind11-2.7.1.ebuild b/dev-python/pybind11/pybind11-2.7.1.ebuild
new file mode 100644
index 000000000000..903b46f35328
--- /dev/null
+++ b/dev-python/pybind11/pybind11-2.7.1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..10} )
+inherit cmake distutils-r1
+
+DESCRIPTION="AST-based Python refactoring library"
+HOMEPAGE="https://pybind11.readthedocs.io/en/stable/"
+SRC_URI="https://github.com/pybind/pybind11/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+
+RDEPEND="
+	dev-cpp/eigen:3
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	export PYBIND11_USE_CMAKE=1
+
+	cmake_src_prepare
+	distutils-r1_python_prepare_all
+}
+
+python_configure() {
+	local mycmakeargs=(
+		# disable forced lto
+		-DPYBIND11_LTO_CXX_FLAGS=
+		-DPYBIND11_INSTALL=ON
+		-DPYBIND11_TEST=$(usex test)
+	)
+	cmake_src_configure
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Compilation only does anything for tests
+	use test && cmake_src_compile
+}
+
+python_test() {
+	cmake_build check
+}
+
+python_install() {
+	distutils-r1_python_install
+	cmake_src_install
+}
-- 
cgit v1.2.3