From 7c59acba5699c9c58090a7a738669669a7307023 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 21 Aug 2021 23:14:26 +0100
Subject: gentoo resync : 21.08.2021

---
 dev-python/pipenv/pipenv-2021.5.29-r2.ebuild | 61 ++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 dev-python/pipenv/pipenv-2021.5.29-r2.ebuild

(limited to 'dev-python/pipenv/pipenv-2021.5.29-r2.ebuild')

diff --git a/dev-python/pipenv/pipenv-2021.5.29-r2.ebuild b/dev-python/pipenv/pipenv-2021.5.29-r2.ebuild
new file mode 100644
index 000000000000..77de678dfaf3
--- /dev/null
+++ b/dev-python/pipenv/pipenv-2021.5.29-r2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+MY_PV=${PV/_beta/b}
+DESCRIPTION="Python Development Workflow for Humans"
+HOMEPAGE="https://github.com/pypa/pipenv https://pypi.org/project/pipenv/"
+SRC_URI="https://github.com/pypa/pipenv/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${PN}-${MY_PV}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+PATCHES=( 
+	"${FILESDIR}/${PN}-${PV//./-}-${PR}-remove-attr-vendor-import.patch"
+	"${FILESDIR}/${PN}-${PV//./-}-${PR}-remove-colorama-vendor-import.patch"
+	)
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4.4[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0.1[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-20.0.35[${PYTHON_USEDEP}]
+	dev-python/virtualenv-clone[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+	)
+"
+
+src_prepare() {
+	# remove vendored version of PyYAML that is backported to Python2
+	rm -vR "${S}/${PN}/patched/yaml2/" || die
+	# remove vendored versions
+	# see https://bugs.gentoo.org/717666
+	rm -vR "${S}/${PN}/vendor/attr/" || die
+	rm -vR "${S}/${PN}/vendor/colorama/" || die
+	rm -vR "${S}/${PN}/vendor/jinja2/" || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	pytest -vvv -x -m "not cli and not needs_internet" tests/unit/ || die
+}
-- 
cgit v1.2.3