From 20ed81714fa97f5845db16a3c142b3b44d820bc4 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 22 Feb 2023 08:27:35 +0000
Subject: gentoo auto-resync : 22:02:2023 - 08:27:35

---
 .../oslo-serialization-5.1.1.ebuild                | 46 ++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 dev-python/oslo-serialization/oslo-serialization-5.1.1.ebuild

(limited to 'dev-python/oslo-serialization/oslo-serialization-5.1.1.ebuild')

diff --git a/dev-python/oslo-serialization/oslo-serialization-5.1.1.ebuild b/dev-python/oslo-serialization/oslo-serialization-5.1.1.ebuild
new file mode 100644
index 000000000000..552a137a31b3
--- /dev/null
+++ b/dev-python/oslo-serialization/oslo-serialization-5.1.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Oslo Serialization library"
+HOMEPAGE="
+	https://opendev.org/openstack/oslo.serialization/
+	https://github.com/openstack/oslo.serialization/
+	https://pypi.org/project/oslo.serialization/
+"
+SRC_URI="$(pypi_sdist_url --no-normalize "${PN/-/.}")"
+S=${WORKDIR}/${P/-/.}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/msgpack-0.5.2[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.2.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+distutils_enable_sphinx doc/source \
+	dev-python/openstackdocstheme
+
+python_prepare_all() {
+	# remove spurious rdep on pbr
+	sed -i -e '/pbr/d' requirements.txt || die
+	distutils-r1_python_prepare_all
+}
-- 
cgit v1.2.3