From 34f71cb8541190212fa250ceb3dafb53f383beea Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 4 Apr 2024 20:14:38 +0100
Subject: gentoo auto-resync : 04:04:2024 - 20:14:38

---
 dev-python/numexpr/numexpr-2.10.0.ebuild | 49 ++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 dev-python/numexpr/numexpr-2.10.0.ebuild

(limited to 'dev-python/numexpr/numexpr-2.10.0.ebuild')

diff --git a/dev-python/numexpr/numexpr-2.10.0.ebuild b/dev-python/numexpr/numexpr-2.10.0.ebuild
new file mode 100644
index 000000000000..f18d721a9310
--- /dev/null
+++ b/dev-python/numexpr/numexpr-2.10.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Fast numerical array expression evaluator for Python and NumPy"
+HOMEPAGE="
+	https://github.com/pydata/numexpr/
+	https://pypi.org/project/numexpr/
+"
+SRC_URI="https://github.com/pydata/numexpr/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+
+DEPEND="
+	>=dev-python/numpy-1.19.0[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/packaging[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	# broken with > 8 CPU threads?
+	# https://github.com/pydata/numexpr/issues/479
+	sed -e 's:test_numexpr_max_threads_empty_string:_&:' \
+		-e 's:test_omp_num_threads_empty_string:_&:' \
+		-i numexpr/tests/test_numexpr.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	pushd "${BUILD_DIR}/install/$(python_get_sitedir)" >/dev/null || die
+	"${EPYTHON}" - <<-EOF || die "Tests failed with ${EPYTHON}"
+		import sys,numexpr
+		sys.exit(0 if numexpr.test(verbosity=2).wasSuccessful() else 1)
+	EOF
+	pushd >/dev/null || die
+}
-- 
cgit v1.2.3