From 9452a6e87b6c2c70513bc47a2470bf9f1168920e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 13 Jun 2020 10:39:22 +0100
Subject: gentoo resync : 13.06.2020

---
 dev-python/notebook/notebook-6.0.3.ebuild | 84 +++++++++++++++++++++++++++++++
 1 file changed, 84 insertions(+)
 create mode 100644 dev-python/notebook/notebook-6.0.3.ebuild

(limited to 'dev-python/notebook/notebook-6.0.3.ebuild')

diff --git a/dev-python/notebook/notebook-6.0.3.ebuild b/dev-python/notebook/notebook-6.0.3.ebuild
new file mode 100644
index 000000000000..a92fb17d8b10
--- /dev/null
+++ b/dev-python/notebook/notebook-6.0.3.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6..9} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Jupyter Interactive Notebook"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-libs/mathjax-2.4
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.8.1[${PYTHON_USEDEP}]
+	>=www-servers/tornado-5.0[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.2.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_core-4.6.1[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-5.3.4[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-4.2.0[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	dev-python/prometheus_client[${PYTHON_USEDEP}]"
+
+# sphinx 2+ seems to have a problem with its github plugin. temporarily adding
+# a version constraint.
+BDEPEND="
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/nose_warnings_filters[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	)
+	"
+
+PATCHES=(
+	"${FILESDIR}/${PN}"-5.7.0-no-mathjax.patch
+	"${FILESDIR}"/${P}-py39.patch
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# disable bundled mathjax
+	sed -i 's/^.*MathJax.*$//' bower.json || die
+
+	# require geckodriver
+	rm -r notebook/tests/selenium || die
+	# trash doesn't seem to work for us
+	sed -e 's:test_delete:_&:' \
+		-i notebook/services/contents/tests/test_manager.py || die
+	sed -e 's:test_checkpoints_follow_file:_&:' \
+		-e 's:test_delete:_&:' \
+		-i notebook/services/contents/tests/test_contents_api.py || die
+	# TODO: high magic, SRE module mismatch
+	sed -e 's:test_connections:_&:' \
+		-e 's:test_main_kernel_handler:_&:' \
+		-i notebook/services/kernels/tests/test_kernels_api.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	ln -sf \
+		"${EPREFIX}/usr/share/mathjax" \
+		"${D}$(python_get_sitedir)/notebook/static/components/MathJax" || die
+}
+
+pkg_preinst() {
+	# remove old mathjax folder if present
+	rm -rf "${EROOT}"/usr/lib*/python*/site-packages/notebook/static/components/MathJax || die
+}
-- 
cgit v1.2.3