From c3bc61051d7f12b4c682efa7a5460bbc8815649e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 7 Jan 2022 22:48:01 +0000
Subject: gentoo resync : 07.01.2022

---
 dev-python/nbconvert/Manifest               |  2 +
 dev-python/nbconvert/nbconvert-6.4.0.ebuild | 73 +++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)
 create mode 100644 dev-python/nbconvert/nbconvert-6.4.0.ebuild

(limited to 'dev-python/nbconvert')

diff --git a/dev-python/nbconvert/Manifest b/dev-python/nbconvert/Manifest
index 2a67b9e8cbbd..8dfceee43f23 100644
--- a/dev-python/nbconvert/Manifest
+++ b/dev-python/nbconvert/Manifest
@@ -1,3 +1,5 @@
 DIST nbconvert-6.3.0.tar.gz 900850 BLAKE2B 8ef7d3bfcb914bf4be064ef440faab283fcc71e53579a681deb343d307a8b39cca2d0b83828b9df7c45ee7e9e06164ba6daa234b678197bc8a3202cd7e560c06 SHA512 efbe18c50e408fcb7d920c5ee070d19e19f0347f7073cf86b45046f3e30bd30ab8174115c539020fbf404faf5fc6e55dc7df1ad27accb45f1b2acf2db1d325e6
+DIST nbconvert-6.4.0.tar.gz 901586 BLAKE2B 85087046fe9a211c077165f47c03e7b025c770e2d409278703ddeef3c84b3d60e1ad28650f67fb9d68b72ad077db5bbd99af5c81ddf94fd7bf67471701dbdc4a SHA512 12662cca240a4c57a41e3bc7fedebd51c6fb83a0740afa7acfcc25424ca544a44b4dbfecfb9edb396360866de0b8fafad124fbb87c46c6f796661a7f40e96f68
 EBUILD nbconvert-6.3.0-r1.ebuild 2081 BLAKE2B d46b5917df34f5cf2b1eebc0e33de809f609f00dfd8b8f0226aa604599692904a966d2295c003dfc20a344ea8cddb05f15eab87635fecf67d62fa841f6bc18f5 SHA512 164265eee260d5f10b5eda9f69701ff771eb3c0f0b556f2226bfa01212f91d2410ef0b651ceeaf7eb3a8349f96a8b07ac92c950d8c77dce9f875ac27408991bf
+EBUILD nbconvert-6.4.0.ebuild 2085 BLAKE2B 30dc55c2f3c140c5228f792429f4d124256c1528b814fd4499aee29e411cf0edc7fc7aa6be5ac5ded3b1987576797643e7b1771fc8cb541d0c2a5970e2590f11 SHA512 405a203e63a8aa512d243652a4aea8fbe426b7efb263fa5611235d7438b16067b4eb41eca7fb227d9df2905429a5d4ad415799fd3e2a990ab39bc2eb9e3d1054
 MISC metadata.xml 527 BLAKE2B a915103b3eaf57236f4257c98354a1e3733771369ac825fa8bbc4f79f0d1a23272dc86e744513620fbee37792e813a15dbb955e633a7c57597c3c38657ed05d3 SHA512 b60a311ce52915dbc12addd4a882670ac96ff8b3be2aa651eaac3d0963d6e73a72eaafd53f90fb685599504857e6bcd0568071962d7696c2605462b77260ad6a
diff --git a/dev-python/nbconvert/nbconvert-6.4.0.ebuild b/dev-python/nbconvert/nbconvert-6.4.0.ebuild
new file mode 100644
index 000000000000..3b031affd2a1
--- /dev/null
+++ b/dev-python/nbconvert/nbconvert-6.4.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Converting Jupyter Notebooks"
+HOMEPAGE="https://nbconvert.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/bleach[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	>=dev-python/entrypoints-0.2.2[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	dev-python/jupyterlab_pygments[${PYTHON_USEDEP}]
+	>=dev-python/mistune-0.7.4[${PYTHON_USEDEP}]
+	dev-python/nbclient[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/pandocfilters-1.4.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.1.1[${PYTHON_USEDEP}]
+	dev-python/testpath[${PYTHON_USEDEP}]
+	www-servers/tornado[${PYTHON_USEDEP}]
+"
+# Skip inkscape on hppa b/c tests should skip it gracefully if not around
+# It's a heavy dependency.
+BDEPEND="
+	test? (
+		dev-python/pebble[${PYTHON_USEDEP}]
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		>=dev-python/jupyter_client-4.2[${PYTHON_USEDEP}]
+		!hppa? ( media-gfx/inkscape )
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	mkdir -p "${HOME}/.local" || die
+	cp -r share "${HOME}/.local/" || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Missing pyppeteer for now
+		# TODO: Doesn't skip?
+		nbconvert/exporters/tests/test_webpdf.py
+		# Needs pyppeteer too
+		'nbconvert/tests/test_nbconvertapp.py::TestNbConvertApp::test_webpdf_with_chromium'
+	)
+
+	distutils_install_for_testing bdist_egg
+	cd "${TEST_DIR}"/lib || die
+	epytest --pyargs nbconvert
+}
+
+pkg_postinst() {
+	if ! has_version app-text/pandoc ; then
+		einfo "Pandoc is required for converting to formats other than Python,"
+		einfo "HTML, and Markdown. If you need this functionality, install"
+		einfo "app-text/pandoc."
+	fi
+}
-- 
cgit v1.2.3