From b0bab803d2f1c96af5760374e2684f9a85591916 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 2 Oct 2022 01:11:51 +0100
Subject: gentoo auto-resync : 02:10:2022 - 01:11:51

---
 .../nautilus-python/nautilus-python-4.0.ebuild     | 51 ++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 dev-python/nautilus-python/nautilus-python-4.0.ebuild

(limited to 'dev-python/nautilus-python/nautilus-python-4.0.ebuild')

diff --git a/dev-python/nautilus-python/nautilus-python-4.0.ebuild b/dev-python/nautilus-python/nautilus-python-4.0.ebuild
new file mode 100644
index 000000000000..3f8b8c7bea70
--- /dev/null
+++ b/dev-python/nautilus-python/nautilus-python-4.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome2 meson python-single-r1
+
+DESCRIPTION="Python bindings for the Nautilus file manager"
+HOMEPAGE="https://projects.gnome.org/nautilus-python/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="gtk-doc"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# Require pygobject:3 and USE=introspection on nautilus for sanity,
+# because no (user) plugins could work without them; meson.build
+# requires pygobject:3 and >=nautilus-43.0
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	>=gnome-base/nautilus-43.0[introspection]
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	gtk-doc? ( dev-util/gtk-doc )
+	>=dev-util/gtk-doc-am-1.14
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature gtk-doc docs)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	mv "${ED}/usr/share/doc/${PN}/"* "${ED}/usr/share/doc/${P}" || die
+	rm -d "${ED}/usr/share/doc/${PN}" || die
+
+	# Directory for systemwide extensions
+	keepdir /usr/share/nautilus-python/extensions
+}
-- 
cgit v1.2.3