From d162ba1860a88062f4cd61f8b52fc303ba0b2991 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 7 Aug 2021 00:16:33 +0100
Subject: gentoo resync : 07.08.2021

---
 .../mysql-connector-python-8.0.26.ebuild           | 53 ++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-python/mysql-connector-python/mysql-connector-python-8.0.26.ebuild

(limited to 'dev-python/mysql-connector-python/mysql-connector-python-8.0.26.ebuild')

diff --git a/dev-python/mysql-connector-python/mysql-connector-python-8.0.26.ebuild b/dev-python/mysql-connector-python/mysql-connector-python-8.0.26.ebuild
new file mode 100644
index 000000000000..454f690c682b
--- /dev/null
+++ b/dev-python/mysql-connector-python/mysql-connector-python-8.0.26.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+inherit distutils-r1
+
+DESCRIPTION="Python client library for MariaDB/MySQL"
+HOMEPAGE="https://dev.mysql.com/downloads/connector/python/"
+SRC_URI="https://github.com/mysql/mysql-connector-python/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+KEYWORDS="~amd64 ~arm ~x86"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="examples test"
+
+BDEPEND=">=dev-libs/protobuf-3.6.1"
+
+RDEPEND="
+	>=dev-db/mysql-connector-c-8.0
+	>=dev-python/protobuf-python-3.6.1[${PYTHON_USEDEP}]
+	dev-python/dnspython[${PYTHON_USEDEP}]
+"
+# tests/mysqld.py does not like MariaDB version strings.
+# See the regex MySQLServerBase._get_version.
+DEPEND="${RDEPEND} test? ( dev-db/mysql[server(+)] )"
+
+# Tests currently fail.
+# mysql.connector.errors.DatabaseError: 1300 (HY000): Invalid utf8 character string: ''
+RESTRICT="test"
+
+DOCS=( README.txt CHANGES.txt README.rst )
+
+python_test() {
+	"${EPYTHON}" unittests.py --with-mysql="${EPREFIX}/usr" --unix-socket="${T}" --mysql-topdir="${T}"
+}
+
+# Yeah, this is really broken, but the extension will only build this way during "install"
+python_install() {
+	distutils-r1_python_install \
+		--with-mysql-capi="${EPREFIX}/usr" \
+		--with-protobuf-include-dir="${EPREFIX}/usr/include/google/protobuf/" \
+		--with-protobuf-lib-dir="${EPREFIX}/usr/$(get_libdir)" \
+		--with-protoc="${EPREFIX}/usr/bin/protoc"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples ; then
+		dodoc -r examples
+	fi
+}
-- 
cgit v1.2.3