From 5bb9ff1ee56d2b5e75e01a7f066d8b0cec84ec02 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 20 Mar 2021 14:27:17 +0000
Subject: gentoo resync : 20.03.2021

---
 dev-python/llvmlite/llvmlite-0.36.0.ebuild | 56 ++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 dev-python/llvmlite/llvmlite-0.36.0.ebuild

(limited to 'dev-python/llvmlite/llvmlite-0.36.0.ebuild')

diff --git a/dev-python/llvmlite/llvmlite-0.36.0.ebuild b/dev-python/llvmlite/llvmlite-0.36.0.ebuild
new file mode 100644
index 000000000000..be873c251504
--- /dev/null
+++ b/dev-python/llvmlite/llvmlite-0.36.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1 llvm
+
+DESCRIPTION="Python wrapper around the llvm C++ library"
+HOMEPAGE="https://llvmlite.pydata.org/"
+SRC_URI="https://github.com/numba/llvmlite/archive/v${PV/_/}.tar.gz -> ${P/_/}.gh.tar.gz"
+S=${WORKDIR}/${P/_/}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples"
+
+LLVM_MAX_SLOT=10
+
+RDEPEND="
+	sys-devel/llvm:${LLVM_MAX_SLOT}
+	sys-libs/zlib:0=
+"
+DEPEND="${RDEPEND}"
+
+python_configure_all() {
+	# upstream's build system is just horrible, and they ignored the PR
+	# fixing it, so let's build the shared lib properly using implicit
+	# make rules
+
+	export LDLIBS=$(llvm-config --libs all)
+	export CXXFLAGS="$(llvm-config --cxxflags) -fPIC ${CXXFLAGS}"
+	export LDFLAGS="$(llvm-config --ldflags) ${LDFLAGS}"
+
+	local files=( ffi/*.cpp )
+	emake -f - <<EOF
+ffi/libllvmlite.so: ${files[*]/.cpp/.o}
+	\$(CXX) -shared \$(CXXFLAGS) \$(LDFLAGS) -o \$@ \$^ \$(LDLIBS)
+EOF
+
+	export LLVMLITE_SKIP_LLVM_VERSION_CHECK=1
+}
+
+python_test() {
+	"${EPYTHON}" runtests.py -v || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
-- 
cgit v1.2.3