From 3a77d78ca92715b58ddac074baa5b25c4baf9a9b Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 9 Sep 2023 22:34:14 +0100
Subject: gentoo auto-resync : 09:09:2023 - 22:34:14

---
 dev-python/libtmux/libtmux-0.23.2.ebuild | 56 ++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 dev-python/libtmux/libtmux-0.23.2.ebuild

(limited to 'dev-python/libtmux/libtmux-0.23.2.ebuild')

diff --git a/dev-python/libtmux/libtmux-0.23.2.ebuild b/dev-python/libtmux/libtmux-0.23.2.ebuild
new file mode 100644
index 000000000000..dccbde0811b2
--- /dev/null
+++ b/dev-python/libtmux/libtmux-0.23.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{9..12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python API for tmux"
+HOMEPAGE="
+	https://libtmux.git-pull.com/
+	https://github.com/tmux-python/libtmux/
+	https://pypi.org/project/libtmux/
+"
+SRC_URI="
+	https://github.com/tmux-python/libtmux/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	>=app-misc/tmux-3.0a
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	libtmux/pane.py::libtmux.pane.Pane.send_keys
+	tests/legacy_api/test_test.py
+)
+
+python_prepare_all() {
+	local issues="https://github.com/tmux-python/libtmux/issues/"
+	sed -r -i "s|:issue:\`([[:digit:]]+)\`|\`issue \1 ${issues}\1\`|" CHANGES || die
+	rm requirements/{doc,dev}.txt || die
+
+	# increase timeouts for tests
+	sed -e 's/0.01/0.1/' -i tests/test_test.py || die
+
+	sed -e '/addopts/s:--doctest-docutils-modules::' \
+		-e '/README\.md/d' \
+		-i setup.cfg || die
+
+	distutils-r1_python_prepare_all
+}
-- 
cgit v1.2.3