From 569e3558cac0a0ecdc6b80debb515b5ed8515df9 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 31 Mar 2023 16:05:26 +0100
Subject: gentoo auto-resync : 31:03:2023 - 16:05:25

---
 dev-python/libsass/Manifest                 |  3 ++
 dev-python/libsass/libsass-0.22.0-r1.ebuild | 62 +++++++++++++++++++++++++++++
 dev-python/libsass/metadata.xml             | 16 ++++++++
 3 files changed, 81 insertions(+)
 create mode 100644 dev-python/libsass/Manifest
 create mode 100644 dev-python/libsass/libsass-0.22.0-r1.ebuild
 create mode 100644 dev-python/libsass/metadata.xml

(limited to 'dev-python/libsass')

diff --git a/dev-python/libsass/Manifest b/dev-python/libsass/Manifest
new file mode 100644
index 000000000000..02c58dbba997
--- /dev/null
+++ b/dev-python/libsass/Manifest
@@ -0,0 +1,3 @@
+DIST libsass-python-0.22.0.gh.tar.gz 55135 BLAKE2B 8495462fa8e6a68bf73ecdf68771c577bad1affa1121c1781dac41c912aae731df88c2b1d1a4ef363e50a98ff1b471e7c45562faa6f2425e8ec5f47f9cf76c6c SHA512 13914b60fe19fc70d197a948a2bc83f7646e4acaa45caed6df68bf2eb10e0a7ef811cdbbcc7a4338f9c1433cba8e316146c20072dc4ff34f51e094ead1bfdcd7
+EBUILD libsass-0.22.0-r1.ebuild 1374 BLAKE2B 126b10a7fc6670e1d1013e9def0b6d41adf75e96c4300ef56d32ca0f9afc01c5346507ca5833a6d498675ebd0bec982c90ac0186a4ef802368e928a49c3f5917 SHA512 dee403917a97301fbaa32e88191504f5df50e7b7d8d220de1ee09452ad839abea958f5d5bba81ab304024e15c5b8bb06d0bc3634253f9cfec426c0dc08c586cb
+MISC metadata.xml 489 BLAKE2B 81f6227a151dbe09e04bc80d25fa9140a08e81d71c531ccf856073c799dbfcb28a0052c5ca8875eb0b52ac93c49098325c02502b7c8ca38e5185601187afe587 SHA512 110e06d1903247bfb00db8cce722d7654c528257e61bfb8281aad749fed6ef385b4aaee3f87f17a8c75eeeafae8f1818d86273900874a776dfa321254b63b67f
diff --git a/dev-python/libsass/libsass-0.22.0-r1.ebuild b/dev-python/libsass/libsass-0.22.0-r1.ebuild
new file mode 100644
index 000000000000..9983462bd91a
--- /dev/null
+++ b/dev-python/libsass/libsass-0.22.0-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+MY_P=libsass-python-${PV}
+DESCRIPTION="A straightforward binding of libsass for Python"
+HOMEPAGE="
+	https://github.com/sass/libsass-python/
+	https://pypi.org/project/libsass/
+"
+SRC_URI="
+	https://github.com/sass/libsass-python/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 x86"
+
+DEPEND="
+	>=dev-libs/libsass-3.6.5
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	test? (
+		dev-python/PyQt5[testlib,${PYTHON_USEDEP}]
+		dev-python/werkzeug[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	echo "${PV}" > .libsass-upstream-version || die
+	distutils-r1_src_prepare
+	export SYSTEM_SASS=1
+	# https://bugs.gentoo.org/881339
+	# the package is applying C++ flags to C sources
+	sed -i -e "s:'-std=gnu++0x',::" -e "s:'-lstdc++'::" setup.py || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# probably broken by removal of sassc
+		sasstests.py::SasscTestCase::test_sassc_stdout
+		# skip the pip tests because they need an internet connection
+		# not relevant for gentoo anyway
+		sasstests.py::DistutilsTestCase::test_build_sass
+		sasstests.py::DistutilsTestCase::test_output_style
+	)
+
+	epytest sasstests.py
+}
diff --git a/dev-python/libsass/metadata.xml b/dev-python/libsass/metadata.xml
new file mode 100644
index 000000000000..4e80ccda26d2
--- /dev/null
+++ b/dev-python/libsass/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>andrewammerlaan@gentoo.org</email>
+		<name>Andrew Ammerlaan</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">sass/libsass-python</remote-id>
+		<remote-id type="pypi">libsass</remote-id>
+	</upstream>
+</pkgmetadata>
-- 
cgit v1.2.3