From 4828c25c25aacf399de429d381288982fd7e0d0e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 14 Nov 2022 00:49:44 +0000
Subject: gentoo auto-resync : 14:11:2022 - 00:49:44

---
 dev-python/libsass/libsass-0.22.0.ebuild | 59 ++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 dev-python/libsass/libsass-0.22.0.ebuild

(limited to 'dev-python/libsass/libsass-0.22.0.ebuild')

diff --git a/dev-python/libsass/libsass-0.22.0.ebuild b/dev-python/libsass/libsass-0.22.0.ebuild
new file mode 100644
index 000000000000..895dfea5ba99
--- /dev/null
+++ b/dev-python/libsass/libsass-0.22.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+MY_P="libsass-python-${PV}"
+DESCRIPTION="A straightforward binding of libsass for Python"
+HOMEPAGE="
+	https://github.com/sass/libsass-python/
+	https://pypi.org/project/libsass/
+"
+SRC_URI="
+	https://github.com/sass/libsass-python/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	>=dev-libs/libsass-3.6.5
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	test? (
+		dev-python/PyQt5[testlib,${PYTHON_USEDEP}]
+		dev-python/werkzeug[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	echo "${PV}" > .libsass-upstream-version || die
+	distutils-r1_src_prepare
+	export SYSTEM_SASS=1
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# probably broken by removal of sassc
+		sasstests.py::SasscTestCase::test_sassc_stdout
+		# skip the pip tests because they need an internet connection
+		# not relevant for gentoo anyway
+		sasstests.py::DistutilsTestCase::test_build_sass
+		sasstests.py::DistutilsTestCase::test_output_style
+	)
+
+	epytest sasstests.py
+}
-- 
cgit v1.2.3