From 3f71901f8c228f4de570abed1831ce3ee425343e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 8 Sep 2018 10:50:14 +0100
Subject: gentoo resync 08.09.2018

---
 dev-python/jeepney/Manifest             |  3 ++
 dev-python/jeepney/jeepney-0.3.1.ebuild | 49 +++++++++++++++++++++++++++++++++
 dev-python/jeepney/metadata.xml         | 13 +++++++++
 3 files changed, 65 insertions(+)
 create mode 100644 dev-python/jeepney/Manifest
 create mode 100644 dev-python/jeepney/jeepney-0.3.1.ebuild
 create mode 100644 dev-python/jeepney/metadata.xml

(limited to 'dev-python/jeepney')

diff --git a/dev-python/jeepney/Manifest b/dev-python/jeepney/Manifest
new file mode 100644
index 000000000000..8189f3cc6103
--- /dev/null
+++ b/dev-python/jeepney/Manifest
@@ -0,0 +1,3 @@
+DIST jeepney-0.3.1.tar.gz 22271 BLAKE2B a8de58e4ef4c4d1874c8995e3726a4bfa26a8db4a63040658c4edfd1742fa1c22de52d8cbee4913b1973279938544481fe2c2aef3138dc0ef724f7a99a39c617 SHA512 ad1a2d220a7626a3bdadf6fba6a591d1b498a9f6bb34607860213efddf49bbe67a4dc2d504decd906c560c519302f1fa45b85ba348156e8bec288f525d502e82
+EBUILD jeepney-0.3.1.ebuild 1041 BLAKE2B 16c36ad2c2e2086ec4682a48d4d00eb572a2aee5d83236023e57f5816c5cb6c0053750701664cf52dc9b340e587e1e1190f8e067e9f0eaf3e0aebd8be4970b0c SHA512 a4ed7d484e4047007b609f8fe5a53e3e32bab810ba12ae53b1cf167ffb0cabc3b9d6eb5079270b3a394aa3eb73657c680d994b718722a29ae257562dbd987a9a
+MISC metadata.xml 432 BLAKE2B 57cc148c4580f5dd579dfbec20c85c80e7d5f2b75397c96f4daa2382e86dbe0547b15ac628fc46bb62c3845becb46cfcfb65027f37839d2d1f843c6872d45e80 SHA512 124413d7ca2a366a651128cd8346aeeb3bd5ceed9b43136fad32861844a078694fa8603e4a11df4d7b37343434bf29bf21d0a0ac6999bf9e9b13f474b93914e4
diff --git a/dev-python/jeepney/jeepney-0.3.1.ebuild b/dev-python/jeepney/jeepney-0.3.1.ebuild
new file mode 100644
index 000000000000..92b469a0334b
--- /dev/null
+++ b/dev-python/jeepney/jeepney-0.3.1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# Python 3.4 and older aren't supported
+PYTHON_COMPAT=( pypy3 python3_{5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, pure Python DBus protocol wrapper"
+HOMEPAGE="https://gitlab.com/takluyver/jeepney"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	pytest -vv || die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/jeepney/metadata.xml b/dev-python/jeepney/metadata.xml
new file mode 100644
index 000000000000..8e28a357224d
--- /dev/null
+++ b/dev-python/jeepney/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">jeepney</remote-id>
+		<remote-id type="gitlab">takluyver/jeepney</remote-id>
+		<bugs-to>https://gitlab.com/takluyver/jeepney/issues</bugs-to>
+	</upstream>
+</pkgmetadata>
-- 
cgit v1.2.3