From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 .../jaraco-collections-1.5.3.ebuild                | 59 ++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 dev-python/jaraco-collections/jaraco-collections-1.5.3.ebuild

(limited to 'dev-python/jaraco-collections/jaraco-collections-1.5.3.ebuild')

diff --git a/dev-python/jaraco-collections/jaraco-collections-1.5.3.ebuild b/dev-python/jaraco-collections/jaraco-collections-1.5.3.ebuild
new file mode 100644
index 000000000000..bd576051b345
--- /dev/null
+++ b/dev-python/jaraco-collections/jaraco-collections-1.5.3.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Models and classes to supplement the stdlib collections module"
+HOMEPAGE="https://github.com/jaraco/jaraco.collections"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc test"
+
+PDEPEND="dev-python/jaraco-text[${PYTHON_USEDEP}]"
+RDEPEND="
+	dev-python/namespace-jaraco[${PYTHON_USEDEP}]
+	dev-python/jaraco-classes[${PYTHON_USEDEP}]
+	>=dev-python/six-1.7.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+		>=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${PDEPEND}
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Override pytest options to skip flake8
+	PYTHONPATH=. py.test --override-ini="addopts=--doctest-modules" \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -name '*.pth' -delete || die
+}
-- 
cgit v1.2.3