From 34efeba333bb7b35b450c57f2045c933b84bd252 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 23 Jul 2022 08:50:16 +0100
Subject: gentoo auto-resync : 23:07:2022 - 08:50:15

---
 .../importlib_resources-5.9.0.ebuild               | 49 ++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 dev-python/importlib_resources/importlib_resources-5.9.0.ebuild

(limited to 'dev-python/importlib_resources/importlib_resources-5.9.0.ebuild')

diff --git a/dev-python/importlib_resources/importlib_resources-5.9.0.ebuild b/dev-python/importlib_resources/importlib_resources-5.9.0.ebuild
new file mode 100644
index 000000000000..7fbce509df31
--- /dev/null
+++ b/dev-python/importlib_resources/importlib_resources-5.9.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=flit
+# This is a backport of Python 3.9's importlib.resources
+PYTHON_COMPAT=( pypy3 python3_8 )
+
+inherit distutils-r1
+
+DESCRIPTION="Read resources from Python packages"
+HOMEPAGE="
+	https://github.com/python/importlib_resources/
+	https://pypi.org/project/importlib-resources/
+"
+SRC_URI="
+	https://github.com/python/importlib_resources/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos ~x64-solaris"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/zipp-3.7.0-r1[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+"
+
+distutils_enable_tests unittest
+
+src_configure() {
+	grep -q 'build-backend = "setuptools' pyproject.toml ||
+		die "Upstream changed build-backend, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "importlib_resources"
+		version = "${PV}"
+		description = "Read resources from Python packages"
+	EOF
+}
-- 
cgit v1.2.3