From 0ed86cb810f23bc360b9f8b955903db4e6595244 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 24 Apr 2023 12:10:02 +0100
Subject: gentoo auto-resync : 24:04:2023 - 12:10:01

---
 dev-python/imageio/imageio-2.28.0.ebuild | 82 ++++++++++++++++++++++++++++++++
 1 file changed, 82 insertions(+)
 create mode 100644 dev-python/imageio/imageio-2.28.0.ebuild

(limited to 'dev-python/imageio/imageio-2.28.0.ebuild')

diff --git a/dev-python/imageio/imageio-2.28.0.ebuild b/dev-python/imageio/imageio-2.28.0.ebuild
new file mode 100644
index 000000000000..30875e33909b
--- /dev/null
+++ b/dev-python/imageio/imageio-2.28.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+BIN_COMMIT=224074bca448815e421a59266864c23041531a42
+DESCRIPTION="Python library for reading and writing image data"
+HOMEPAGE="
+	https://imageio.readthedocs.io/en/stable/
+	https://github.com/imageio/imageio/
+	https://pypi.org/project/imageio/
+"
+SRC_URI="
+	https://github.com/imageio/imageio/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	test? (
+		https://github.com/imageio/imageio-binaries/raw/${BIN_COMMIT}/images/chelsea.png
+			-> ${PN}-chelsea.png
+		https://github.com/imageio/imageio-binaries/raw/${BIN_COMMIT}/images/cockatoo.mp4
+			-> ${PN}-cockatoo.mp4
+	)
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+# over 50% of tests rely on Internet
+PROPERTIES="test_network"
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-python/numpy-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/pillow-8.3.2[${PYTHON_USEDEP}]
+	media-libs/freeimage
+"
+# requests for fsspec[github]
+BDEPEND="
+	test? (
+		dev-python/fsspec[${PYTHON_USEDEP}]
+		dev-python/imageio-ffmpeg[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/tifffile[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	local PATCHES=(
+		# block silently downloading vulnerable libraries from the Internet
+		"${FILESDIR}"/imageio-2.22.0-block-download.patch
+	)
+
+	if use test; then
+		mkdir -p "${HOME}"/.imageio/images || die
+		local i
+		for i in chelsea.png cockatoo.mp4; do
+			cp "${DISTDIR}/${PN}-${i}" "${HOME}/.imageio/images/${i}" || die
+		done
+	fi
+
+	distutils-r1_src_prepare
+}
+
+EPYTEST_DESELECT=(
+	# Fails because of system installed freeimage
+	tests/test_core.py::test_findlib2
+	# Tries to download ffmpeg binary ?!
+	tests/test_ffmpeg.py::test_get_exe_installed
+	# blocked by our patch
+	tests/test_core.py::test_fetching
+	tests/test_core.py::test_request
+	# known broken
+	# https://github.com/imageio/imageio/issues/890
+	tests/test_freeimage.py::test_exr_write
+)
-- 
cgit v1.2.3