From aca0af8133e724b7edf0b5c6efe12c39077a3dc9 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 30 Jul 2023 16:42:15 +0100
Subject: gentoo auto-resync : 30:07:2023 - 16:42:14

---
 dev-python/graph-tool/graph-tool-2.56.ebuild | 84 ----------------------------
 1 file changed, 84 deletions(-)
 delete mode 100644 dev-python/graph-tool/graph-tool-2.56.ebuild

(limited to 'dev-python/graph-tool/graph-tool-2.56.ebuild')

diff --git a/dev-python/graph-tool/graph-tool-2.56.ebuild b/dev-python/graph-tool/graph-tool-2.56.ebuild
deleted file mode 100644
index a856d2584fed..000000000000
--- a/dev-python/graph-tool/graph-tool-2.56.ebuild
+++ /dev/null
@@ -1,84 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..11} )
-
-inherit check-reqs python-r1 toolchain-funcs
-
-if [[ ${PV} == *9999 ]]; then
-	EGIT_REPO_URI="https://git.skewed.de/count0/graph-tool.git"
-	inherit autotools git-r3
-else
-	SRC_URI="https://downloads.skewed.de/${PN}/${P}.tar.bz2"
-	KEYWORDS="~amd64"
-fi
-
-DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
-HOMEPAGE="https://graph-tool.skewed.de/"
-
-LICENSE="GPL-3"
-SLOT="0"
-IUSE="+cairo openmp"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-RDEPEND="
-	${PYTHON_DEPS}
-	dev-libs/boost:=[context,python,${PYTHON_USEDEP}]
-	dev-libs/expat
-	dev-python/numpy[${PYTHON_USEDEP}]
-	dev-python/scipy[${PYTHON_USEDEP}]
-	sci-mathematics/cgal:=
-	dev-python/matplotlib[${PYTHON_USEDEP}]
-	cairo? (
-		dev-cpp/cairomm:0
-		dev-python/pycairo[${PYTHON_USEDEP}]
-		x11-libs/cairo[X]
-	)"
-DEPEND="${RDEPEND}
-	dev-cpp/sparsehash"
-BDEPEND="virtual/pkgconfig"
-
-# bug 453544
-CHECKREQS_DISK_BUILD="6G"
-
-pkg_pretend() {
-	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
-	check-reqs_pkg_pretend
-}
-
-pkg_setup() {
-	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
-}
-
-src_prepare() {
-	default
-	[[ ${PV} == *9999 ]] && eautoreconf
-	python_copy_sources
-}
-
-src_configure() {
-	my_configure() {
-		econf \
-			--disable-static \
-			$(use_enable openmp) \
-			$(use_enable cairo) \
-			--with-boost-python="boost_${EPYTHON/./}"
-	}
-	python_foreach_impl run_in_build_dir my_configure
-}
-
-src_compile() {
-	python_foreach_impl run_in_build_dir emake
-}
-
-src_install() {
-	my_python_install() {
-		default
-		python_optimize
-	}
-	python_foreach_impl run_in_build_dir my_python_install
-
-	find "${ED}" -name '*.la' -delete || die
-}
-- 
cgit v1.2.3