From 7c59acba5699c9c58090a7a738669669a7307023 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 21 Aug 2021 23:14:26 +0100
Subject: gentoo resync : 21.08.2021

---
 .../geventhttpclient/geventhttpclient-1.5.1.ebuild | 49 ++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 dev-python/geventhttpclient/geventhttpclient-1.5.1.ebuild

(limited to 'dev-python/geventhttpclient/geventhttpclient-1.5.1.ebuild')

diff --git a/dev-python/geventhttpclient/geventhttpclient-1.5.1.ebuild b/dev-python/geventhttpclient/geventhttpclient-1.5.1.ebuild
new file mode 100644
index 000000000000..6595b2fc1c19
--- /dev/null
+++ b/dev-python/geventhttpclient/geventhttpclient-1.5.1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A high performance, concurrent HTTP client library for Python using gevent"
+HOMEPAGE="https://github.com/gwik/geventhttpclient"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+RDEPEND="
+	app-arch/brotli[python,${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/gevent[events,${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Avoid ModuleNotFoundError for tests we skip later
+	sed -i '/^import dpkt.ssl/d' src/geventhttpclient/tests/test_ssl.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# These SNI tests require dpkt which is not in the tree
+		src/geventhttpclient/tests/test_ssl.py::test_implicit_sni_from_host_in_ssl
+		src/geventhttpclient/tests/test_ssl.py::test_implicit_sni_from_header_in_ssl
+		src/geventhttpclient/tests/test_ssl.py::test_explicit_sni_in_ssl
+	)
+	# Append to sys.path to avoid ImportError
+	# https://bugs.gentoo.org/667758
+	# Skip tests which require internet access
+	epytest --import-mode=append -m "not online"
+}
-- 
cgit v1.2.3