From 8b4ace9c50842c5b83401ea7b179dcab940387e1 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 23 Sep 2020 10:22:15 +0100
Subject: gentoo resync : 23.09.2020

---
 dev-python/dulwich/dulwich-0.20.6.ebuild | 53 ++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-python/dulwich/dulwich-0.20.6.ebuild

(limited to 'dev-python/dulwich/dulwich-0.20.6.ebuild')

diff --git a/dev-python/dulwich/dulwich-0.20.6.ebuild b/dev-python/dulwich/dulwich-0.20.6.ebuild
new file mode 100644
index 000000000000..28c16b903611
--- /dev/null
+++ b/dev-python/dulwich/dulwich-0.20.6.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Pure-Python implementation of the Git file formats and protocols"
+HOMEPAGE="https://github.com/jelmer/dulwich/ https://pypi.org/project/dulwich/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		!hppa? ( !ia64? (
+			dev-python/gevent[${PYTHON_USEDEP}]
+			dev-python/geventhttpclient[${PYTHON_USEDEP}]
+		) )
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/python-fastimport[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_sphinx docs
+
+python_test() {
+	# remove interference from the tests that do stuff like user.name
+	unset GIT_AUTHOR_NAME GIT_AUTHOR_EMAIL GIT_AUTHOR_DATE \
+		GIT_COMMITTER_NAME GIT_COMMITTER_EMAIL GIT_COMMITTER_DATE EMAIL
+	# Do not use make check which rebuilds the extension and uses -Werror,
+	# causing unexpected failures.
+	"${EPYTHON}" -m unittest -v dulwich.tests.test_suite \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3