From c8fd0d84af0bfd1949542adc2cbb735b1d28f9ed Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 7 May 2021 01:33:16 +0100
Subject: gentoo resync : 07.05.2021

---
 dev-python/django/django-2.2.20.ebuild | 93 ----------------------------------
 1 file changed, 93 deletions(-)
 delete mode 100644 dev-python/django/django-2.2.20.ebuild

(limited to 'dev-python/django/django-2.2.20.ebuild')

diff --git a/dev-python/django/django-2.2.20.ebuild b/dev-python/django/django-2.2.20.ebuild
deleted file mode 100644
index 27e7c9338845..000000000000
--- a/dev-python/django/django-2.2.20.ebuild
+++ /dev/null
@@ -1,93 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-DISTUTILS_USE_SETUPTOOLS=rdepend
-PYTHON_COMPAT=( python3_{7..9} )
-PYTHON_REQ_USE='sqlite?,threads(+)'
-
-inherit bash-completion-r1 distutils-r1 optfeature verify-sig
-
-MY_P=${P^}
-DESCRIPTION="High-level Python web framework"
-HOMEPAGE="https://www.djangoproject.com/ https://pypi.org/project/Django/"
-SRC_URI="
-	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
-	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )"
-S="${WORKDIR}/${MY_P}"
-
-LICENSE="BSD"
-# admin fonts: Roboto (media-fonts/roboto)
-LICENSE+=" Apache-2.0"
-# admin icons, jquery, xregexp.js
-LICENSE+=" MIT"
-SLOT="0"
-KEYWORDS="amd64 arm64 ~ppc ~ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
-IUSE="doc sqlite test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-python/pytz[${PYTHON_USEDEP}]
-	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]"
-BDEPEND="
-	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
-	test? (
-		$(python_gen_impl_dep sqlite)
-		${RDEPEND}
-		dev-python/docutils[${PYTHON_USEDEP}]
-		dev-python/jinja[${PYTHON_USEDEP}]
-		dev-python/numpy[${PYTHON_USEDEP}]
-		dev-python/pillow[webp,${PYTHON_USEDEP}]
-		dev-python/pyyaml[${PYTHON_USEDEP}]
-		dev-python/selenium[${PYTHON_USEDEP}]
-		dev-python/tblib[${PYTHON_USEDEP}]
-		sys-devel/gettext
-	)
-	verify-sig? ( app-crypt/openpgp-keys-django )
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-2.0.7-bashcomp.patch
-)
-
-distutils_enable_sphinx docs --no-autodoc
-
-VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
-
-src_unpack() {
-	if use verify-sig; then
-		cd "${DISTDIR}" || die
-		verify-sig_verify_signed_checksums \
-			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
-		cd "${WORKDIR}" || die
-	fi
-
-	default
-}
-
-python_test() {
-	# Tests have non-standard assumptions about PYTHONPATH,
-	# and don't work with ${BUILD_DIR}/lib.
-	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
-		die "Tests fail with ${EPYTHON}"
-}
-
-python_install_all() {
-	newbashcomp extras/django_bash_completion ${PN}-admin
-	bashcomp_alias ${PN}-admin django-admin.py
-
-	distutils-r1_python_install_all
-}
-
-pkg_postinst() {
-	optfeature_header "Additional Backend support can be enabled via:"
-	optfeature "MySQL backend support" dev-python/mysqlclient
-	optfeature "PostgreSQL backend support" dev-python/psycopg:2
-	optfeature_header
-	optfeature "GEO Django" "sci-libs/gdal[geos]"
-	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
-	optfeature "ImageField Support" dev-python/pillow
-	optfeature "Password encryption" dev-python/bcrypt
-	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
-}
-- 
cgit v1.2.3